3

こんにちは皆さん、酵母コロニープレートの画像から強度の値をいくつか持っています。強度値からピーク値を見つけることができる必要があります。以下は、グラフ化されたときに値がどのように見えるかを示す画像の例です。

値の例 

5.7
5.3
8.2
16.5
34.2
58.8
**75.4**
75
65.9
62.6
58.6
66.4
71.4
53.5
40.5
26.8
14.2
8.6
5.9
7.7
14.9
30.5
49.9
69.1
**75.3**
69.8
58.8
57.2
56.3
67.1
69
45.1
27.6
13.4
8
5

これらの値は 75.4 と 75.3 に 2 つのピークを示しており、値が増加してから減少することがわかります。変化はいつも同じではありません。

強度値のグラフ

http://lh4.ggpht.com/_aEDyS6ECO8s/THKTLgDPhaI/AAAAAAAAAio/HQW7Ut-HBhA/s400/peaks.png調査より

私が考えていることの 1 つは、各グループ、つまり山をハッシュに格納し、グループ内の最大値を探すことです。私が見ている問題の 1 つは、各グループの境界を決定する方法です。

ここに私がこれまでに持っているコードへのリンクがあります: http://paste-it.net/public/y485822/

完全なデータ セットへのリンクは次のとおりです: http://paste-it.net/public/ub121b4/

私はPerlでコードを書いています。どんな助けでも大歓迎です。ありがとうございました

4

3 に答える 3

6

ピークをどの程度ローカルにするかを決定する必要があります。ここでのアプローチは、データの広い領域内で山と谷を見つけます。

use strict;
use warnings;

my @data = (
    5.7, 5.3, 8.2, 16.5, 34.2, 58.8, 75.4, 75, 65.9, 62.6,
    58.6, 66.4, 71.4, 53.5, 40.5, 26.8, 14.2, 8.6, 5.9, 7.7,
    14.9, 30.5, 49.9, 69.1, 75.3, 69.8, 58.8, 57.2, 56.3, 67.1,
    69, 45.1, 27.6, 13.4, 8, 5,
);

# Determine mean. Or use Statistics::Descriptive.
my $sum;
$sum += $_ for @data;
my $mean = $sum / @data;

# Make a pass over the data to find contiguous runs of values
# that are either less than or greater than the mean. Also
# keep track of the mins and maxes within those groups.
my $group = -1;
my $gt_mean_prev = '';
my @mins_maxs;
my $i = -1;

for my $d (@data){
    $i ++;
    my $gt_mean = $d > $mean ? 1 : 0;

    unless ($gt_mean eq $gt_mean_prev){
        $gt_mean_prev = $gt_mean;
        $group ++;
        $mins_maxs[$group] = $d;
    }

    if ($gt_mean){
        $mins_maxs[$group] = $d if $d > $mins_maxs[$group];
    }
    else {
        $mins_maxs[$group] = $d if $d < $mins_maxs[$group];
    }

    $d = {
        i       => $i,
        val     => $d,
        group   => $group,
        gt_mean => $gt_mean,
    };
}

# A fun picture.
for my $d (@data){
    printf
        "%6.1f  %2d  %1s  %1d  %3s  %s\n",
        $d->{val},
        $d->{i},
        $d->{gt_mean} ? '+' : '-',
        $d->{group},
        $d->{val} == $mins_maxs[$d->{group}] ? '==>' : '',
        '.' x ($d->{val} / 2),
    ;

}

出力：

   5.7   0  -  0       ..
   5.3   1  -  0  ==>  ..
   8.2   2  -  0       ....
  16.5   3  -  0       ........
  34.2   4  -  0       .................
  58.8   5  +  1       .............................
  75.4   6  +  1  ==>  .....................................
  75.0   7  +  1       .....................................
  65.9   8  +  1       ................................
  62.6   9  +  1       ...............................
  58.6  10  +  1       .............................
  66.4  11  +  1       .................................
  71.4  12  +  1       ...................................
  53.5  13  +  1       ..........................
  40.5  14  -  2       ....................
  26.8  15  -  2       .............
  14.2  16  -  2       .......
   8.6  17  -  2       ....
   5.9  18  -  2  ==>  ..
   7.7  19  -  2       ...
  14.9  20  -  2       .......
  30.5  21  -  2       ...............
  49.9  22  +  3       ........................
  69.1  23  +  3       ..................................
  75.3  24  +  3  ==>  .....................................
  69.8  25  +  3       ..................................
  58.8  26  +  3       .............................
  57.2  27  +  3       ............................
  56.3  28  +  3       ............................
  67.1  29  +  3       .................................
  69.0  30  +  3       ..................................
  45.1  31  +  3       ......................
  27.6  32  -  4       .............
  13.4  33  -  4       ......
   8.0  34  -  4       ....
   5.0  35  -  4  ==>  ..
于 2010-08-23T16:30:59.523 に答える
2

コントロールデータセットはありますか？もしそうなら、酵母強度とコントロール画像の間の単純な対数比などを使用してデータを正規化することをお勧めします。

次に、ChiPOTle の perl ポートを使用して重要なピークを取得できます。これは、ローカル/グローバル最大値などを検索するよりもはるかに堅牢に聞こえます。

ChiPOTle は「ChIP チップ マイクロ アレイ データの分析に使用されるピーク検出アルゴリズム」ですが、他の多くのアプリケーション (ChIP-seq など、あなたの場合よりも本来の目的に近いことは確かです) でうまく使用しています。

結果の log(yeast/control) 負の値は、有意性推定のためのガウス バックグラウンド モデルを構築するために使用されます。次に、アルゴリズムは、複数のテストの修正に誤検出率を使用します。

これが元の論文です。

于 2010-08-24T06:03:28.417 に答える
2 
my @data = ...;

# filter out sequential duplicate values
my @orig_index = 0;
my @deduped = $data[0];
for my $index ( 1..$#data ) {
    if ( $data[$index] != $data[$index-1] ) {
        push @deduped, $data[$index];
        push @orig_index, $index;
    }
}

# add a sentinel (works for both ends)
push @deduped, -9**9**9;

my @local_maxima_indexes;
for my $index ( 0..$#deduped-1 ) {
    if ( $deduped[$index] > $deduped[$index-1] && $deduped[$index] > $deduped[$index+1] ) {
        push @local_maxima_indexes, $orig_index[$index];
    }
}

これは、最初の値を極大値と見なし、71.4 と 69 の値も考慮していることに注意してください。含めたい値をどのように区別しているのかわかりません。

于 2010-08-23T16:33:14.453 に答える