f# - f# でボイラープレートを破棄する

Question

私はHaskell プログラミング言語でScrap Your Boilerplateライブラリと Uniplate ライブラリを使用しましたが、判別共用体に対する汎用プログラミングの形式が非常に役立つことがわかりました。f# プログラミング言語に同等のライブラリはありますか?

Answer 1

私が知っていることではありません。言語/コンパイラに組み込まれているサポートがない場合、唯一の選択肢はリフレクションベースのバージョンだと思います。( Uniplateがどのように実装されているかはわかりません - そうですか?)

元のプレゼンテーションの例に基づいたリフレクション ベースのバージョンのコードを次に示します。その制限について深く考えたことはありませんが、これは私が推測していたよりもはるかに簡単に書くことができました。

type Company = C of Dept list
and Dept = D of Name * Manager * SubUnit list
and SubUnit = | PU of Employee | DU of Dept
and Employee = E of Person * Salary
and Person = P of Name * Address
and Salary = S of float
and Manager = Employee
and Name = string
and Address = string

let data = C [D("Research",E(P("Fred","123 Rose"),S 10.0),
                  [PU(E(P("Bill","15 Oak"),S 5.0))])]
printfn "%A" data

open Microsoft.FSharp.Reflection 
let everywhere<'a,'b>(f:'a->'a, src:'b) =   // '
    let ft = typeof<'a>             // '
    let rec traverse (o:obj) =
        let ot = o.GetType()
        if ft = ot then
            f (o :?> 'a) |> box    // '
        elif FSharpType.IsUnion(ot) then
            let info,vals = FSharpValue.GetUnionFields(o, ot)
            FSharpValue.MakeUnion(info, vals |> Array.map traverse)
        else 
            o
    traverse src :?> 'b       // '

let incS (S x) = S(x+1.0) 

let newData = everywhere(incS, data)
printfn "%A" newData

everywhere関数は、任意の DU の構造全体を横断し、機能するタイプの各ノードに関数を適用し、他fのfすべてのノードはそのままにします。