7

関数型プログラミングの機能を理解するために、いくつかの基本的な関数をまとめました。これらを組み合わせて複雑な正規表現を作成できます。いくつかのテストの後、これが機能することがわかりましたが、機能する言語で恐ろしいコードを書くことができます。これはプロの F# プログラマーが書いているようなコードですか、それとも私が機能を悪用しているのでしょうか?

注： test具体的には私が言及しているものです。

type State = { input:string; index:int; succeeded:bool }
type Matcher = State -> State

let term (cs:char Set)  =
    fun s ->
        if s.succeeded && s.index < s.input.Length && cs.Contains s.input.[s.index] then  
            { input = s.input; index = s.index + 1; succeeded = true }
        else 
            { input = s.input; index = s.index; succeeded = false }

let quantify (term, min, max) =
    let rec inner (s:State, count) =
        if s.succeeded && s.index < s.input.Length && count <= max then
            inner (term { input = s.input; index = s.index + 1; succeeded = true }, count + 1) 
        elif count >= min && count <= max then
            { input = s.input; index = s.index - 1; succeeded = true }    
        else 
            s         
    fun s -> inner (s, 0) 

let disjunction leftTerm rightTerm =
    fun s ->
        let left = leftTerm s
        if not left.succeeded then
            let right = rightTerm s  
            if not right.succeeded then
                { input = s.input; index = s.index; succeeded = false }
            else
                right
        else
            left 

let matcher input terms =
    let r = terms  { input = input; index = 0; succeeded = true } 
    if r.succeeded then r.input.Substring (0, r.index) else null

let test = // (abc|xyz)a{2,3}bc
    disjunction // (abc|xyz)
        (term (set "a") >> term (set "b") >> term (set "c"))
        (term (set "x") >> term (set "y") >> term (set "z"))  
    >> quantify (term (set "a"), 2, 3) // (a{2,3})
    >> term (set "b") // b  
    >> term (set "c") // c

let main () : unit =
    printfn "%s" (matcher "xyzaabc" test)
    System.Console.ReadKey true |> ignore

main()
4

2 に答える 2

8

コードは私にはかなり良さそうです。

これがあなたの意図なのか偶然なのかはわかりませんが、多くの学術論文のトピックである「パーサーコンビネーター」に非常に似たものを実装しています:-)。Monadic Parser Combinatorsは非常に読みやすいと思います(Haskell の例がありますが、F# に変換できるはずです)。

関数合成演算子について。私は通常、この演算子を使いすぎることはあまり好きではありません。なぜなら、この演算子はコードを難読化することが多いからです。>>ただし、あなたの例では、 「このグループの後にはそのグループが続く必要がある」という意味を簡単に想像できるため、解釈が容易です。

私が行う唯一のマイナーな変更は、操作に適切なカスタム オペレーターを選択し、disjunctionさらにいくつかの基本的な操作を定義することです。たとえば、次のように記述できます。

// Test against several terms in sequence
let sequence terms = (fun state -> terms |> Seq.fold (>>) state)
// Test for a substring
let substring s = sequence [ for c in s -> term (set [c]) ]

let test = // (abc|xyz)a{2,3}bc 
  ( substring "abc" <|> substring "xyz" )
  >> quantify 2 3 (term (set "a")) // (a{2,3}) 
  >> substring "bc" // bc

これはより高レベルの説明であるため、一部の>>演算子を削除して、より説明的な (およびカプセル化する>>) 関数を優先します。quantifyまた、トリプルの代わりに複数の引数を取るように変更しました (これはマイナーな変更です)。

これをさらに試してみたい場合は、この記事を参照して、parser { .. }構文を使用できる F# 計算式ビルダーを作成してみてください。

于 2010-09-01T03:02:07.223 に答える
3

これは一般的に良いスタイルですが、いくつかのトリックが欠けており、まだかなりの冗長性があります。多分もっとこのように:

let valid (s: State) = s.succeeded && s.index < s.input.Length
...
let disjunction leftTerm rightTerm s =
  let left = leftTerm s
  if left.succeeded then left else
    let right = rightTerm s  
    if right.succeeded then right else
      { s with succeeded = false }
...
let test =
  let f s = set s |> term
  let (++) s t = f s >> f t
  disjunction ("a" ++ "b" ++ "c") ("x" ++ "y" ++ "z")  
  >> quantify (f "a", 2, 3)
  >> "b" ++ "c"

デバッグがはるかに簡単になるため、クロージャーではなく計算を表す値を累積することを好む場合があります。

于 2010-09-01T11:51:22.230 に答える