arrays - 2次元配列をループするには?

Question

これを画面に出力していた後、次のような2次元配列があります。

array
1   
array
1   0600
2   
array
1   0
3   
array
1   0600
4   
array
1   0
5   
array
1   0615
6   
array
1   0
7   
array
1   0615
8   
array
1   0
9   
array
1   0630
10  
array
1   0
11  
array
1   0630
12  
array
1   1 

したがって、配列をループして、値を次の順序で出力したいと思います。

0600   0
0600   0
0615   0
0615   0
0630   0  
0630   1

配列を作成したコードは次のとおりです。

<cfloop list="#ListGetAt(dataList,i,",")#" index="z" delimiters="|">
    <cfoutput query="getR" group="theYear">
        <cfset name = myArray.append([z])>
        <cfif Description eq z>
            <cfset count = myArray.append([theCount])>
        <cfelse>
            <cfset count = myArray.append([0])>
        </cfif>
    </cfoutput>
</cfloop>

では、上で示したように、この 2 つのレコードを順番にループして取得するにはどうすればよいでしょうか? 私はこれを試しましたが、うまくいきませんでした：

<cfoutput>
    <cfloop from="1" to="#arraylen(myArray)#" index="i">
        <cfloop array="#myArray#" index="j">
            #i# - #myArray[1][j]#<br/>
        </cfloop>
    </cfloop>
</cfoutput>

編集： このコードを使用したとき：

<cfloop array="#myArray#" index="i"> 
    <cfloop array="#myArray#" index="j"> 
        <cfoutput> #myArray[i][j]#<br/> </cfoutput> 
    </cfloop> 
</cfloop> 

このエラーが発生しました：

The value coldfusion.runtime.Array cannot be converted to a number.

誰かがこの問題を解決できる場合は、私に知らせてください。

Answer 1

これは、2 次元配列から出力を取得する方法です。

<cfscript>
data = [
    ["0600", 0],
    ["0600", 0],
    ["0615", 0],
    ["0615", 0],
    ["0630", 0],
    ["0630", 1]
];

// script version
for (foo in data) {
    writeOutput(foo[1] & " " & foo[2] & "<br>");
}

</cfscript>

<cfoutput>
tag version...<br>
<cfloop array="#data#" index="foo">
    #foo[1]# #foo[2]#<br>
</cfloop>
</cfoutput>

ここでの使用例: http://trycf.com/gist/86b42b56ef7348ec0d44/acf2016?theme=monokai

ただし、構造体 (キーと値のペア) の配列の方が簡単な方法であると思われるのに、なぜ 2 次元配列を使用しているのかわかりません。

例えば：

<cfscript>
data = [
    {key:"0600", count:0},
    {key:"0600", count:0},
    {key:"0615", count:0},
    {key:"0615", count:0},
    {key:"0630", count:0},
    {key:"0630", count:1}
];

// script version
for (foo in data) {
    writeoutput(foo.key & " " & foo.count & "<br>");
}

</cfscript>

<cfoutput>
tag version...<br>
<cfloop array="#data#" index="foo">
    #foo.key# #foo.count#<br>
</cfloop>
</cfoutput>