dm-script - 複数の SI 取得を自動的に実行する方法は?

Question

複数の EELS スペクトル画像を連続して取得する Gatan DigitalMicrograph スクリプトを作成したいと思います。スペクトル画像 (SI) データを取得し、3 次元画像を配列に格納するコマンドがあれば、私の計画は達成されます。しかし、リファレンス マニュアルから SI イメージング モードの適切なコマンドを見つけることができませんでした。この場合、どのコマンドを使用すればよいですか? 私の目的に役立つ知識はありますか？いくつかの知恵を共有していただければ幸いです。

Answer 1

SI Acquisition コマンドを使用して SI 取得を複数回繰り返し、取得したデータ セットを「名前変更」する方法の短いデモ スクリプト。

// Assumptions:  
// -  GMS 2.3 used
// -  Valid survey image and ROI already assigned
// -  SI array size already defined
// -  Signals and other SI settings made

number SIx, SIy 
SIGetFieldValue( "2D Array, X samples", SIx )
SIGetFieldValue( "2D Array, Y samples", SIy )
Result("\n SI size:"+ SIx + "x" + SIy )

// Start SI
number nSI = 3
for (number i=0; i<nSI; i++ )
{
    SIInvokeButton( "Start/Stop", 1 )
    while(SIIsAcquisitionActive()) yield()
    sleep(0.5)          // Small delay needed to allow DM finish SI acquisition clean-up

    // Find (and rename) SI DataSets
    number nImgDoc = CountImageDocuments()
    string findStr = "Spectrum Image"
    for (number d=0; d<nImgDoc; d++ )
    {
        string docName = GetImageDocument(d).ImageDocumentGetName()
        if ( find(docName,findStr) == (len(docName)-len(findStr)) )
        {
            GetImageDocument(d).ImageDocumentSetName( docName + "#"+(d+1) )
        }   
    }
}
OKDialog( "Done" )