2

インストーラーに VCL スタイル (Inno Setup 5.5.6 (a)) を追加しようとしています。インストール中はスタイルが正しく読み込まれるが、アンインストールしようとするとエラーが発生する

ランタイム エラー (at-1:0): dll:VclStylesInno.dll をインポートできません。

また、プログラムをアンインストールできません。

私に何ができるか知っている人はいますか？
助けてくれてありがとう

#define VCLStylesSkinPath "{localappdata}\VCLStylesSkin"

[Files]
;Install
Source: "VclStylesinno.dll"; DestDir: "{app}"; Flags: dontcopy
Source: "Styles\Auric.vsf"; DestDir: "{app}"; Flags: dontcopy
;Uninstall
Source: "VclStylesinno.dll"; DestDir: "{#VCLStylesSkinPath}"; \
  Flags: uninsneveruninstall
Source: "Styles\Auric.vsf"; DestDir: "{#VCLStylesSkinPath}"; \
  Flags: uninsneveruninstall

[Code]

{ Import the LoadVCLStyle function from VclStylesInno.DLL }
procedure LoadVCLStyle(VClStyleFile: String);
  external 'LoadVCLStyleA@files:VclStylesInno.dll stdcall setuponly';
procedure LoadVCLStyle_UnInstall(VClStyleFile: String);
  external 'LoadVCLStyleA@VclStylesInno.dll stdcall uninstallonly';

{ Import the UnLoadVCLStyles function from VclStylesInno.DLL }
procedure UnLoadVCLStyles;
  external 'UnLoadVCLStyles@files:VclStylesInno.dll stdcall setuponly';
procedure UnLoadVCLStyles_UnInstall;
  external 'UnLoadVCLStyles@VclStylesInno.dll stdcall uninstallonly';
    
function InitializeUninstall: Boolean;
begin
  Result := True;
  LoadVCLStyle_UnInstall(ExpandConstant('Styles\Auric.vsf'));
end;

procedure DeinitializeUninstall();
begin
  UnLoadVCLStyles_UnInstall;
end;
4

1 に答える 1

2

のアンインストール コピーへのパスを指定していませんVclStylesInno.dll。

これは正しい方法です：

procedure LoadVCLStyle_UnInstall(VClStyleFile: String); 
  external 'LoadVCLStyleA@{#VCLStylesSkinPath}\VclStylesInno.dll stdcall uninstallonly';

次回は、VCL Styles for Inno Setup をアンインストールするための公式の指示に従ってください。

詳細と、公式のソリューションよりも優れたソリューションについては、Load external DLL for uninstall process in Inno Setupも参照してください。

于 2016-04-20T13:43:21.200 に答える