2

多くの開いている接続がある開発サーバーにアプリがあるようです (そこにあるはずですが、それらを開くためにいくつかの悪いデータレイヤーが使用され、それらを閉じるのを忘れていました)。サーバー上で他のアプリを実行し続けることができるように、それらを閉じたいだけです。すべての接続を強制的に閉じるにはどうすればよいですか?

4

4 に答える 4

6

次のスクリプトを使用して、特定のホスト/ログインから非アクティブなセッションを強制終了します。スケジュールされたジョブからそれを使用することもできます。もちろん、アプリ層を修正することを優先する必要があります。 

SET NOCOUNT ON;

DECLARE @host VARCHAR(50), @login NVARCHAR(128);

SET @host = 'fooHost'; --NULL to kill sessions from all hosts.
SET @login = 'fooLogin';

DECLARE @cmd NVARCHAR(255);
DECLARE @possition INT, @total INT, @selSpid SMALLINT;
DECLARE @spidInfo TABLE
(
    [id] INT IDENTITY(1,1),
    spid SMALLINT,
    loginame NVARCHAR(128)
);

INSERT @spidInfo(spid, loginame)
SELECT session_id, login_name 
FROM sys.dm_exec_sessions
WHERE is_user_process = 1 AND [status] = 'sleeping' AND 
    login_name = @login AND [host_name] = COALESCE(@host, [host_name]);

SELECT @total = @@IDENTITY, @selSpid = 0, @possition = 0;

WHILE @possition < @total
    BEGIN
        SELECT TOP 1 @selSpid = spid, @possition = [id]
        FROM @spidInfo
        WHERE [ID] > @possition

        SET @cmd = N'KILL ' + CAST(@selSpid AS NVARCHAR(10));
        EXEC sp_executesql @cmd;
        PRINT 'SessionId = ' + CAST(@selSpid AS NVARCHAR(10)) + '[' + @login + 
            '] killed by ' + system_user + ' at ' + CAST(GETDATE() AS VARCHAR(50));
    END;

IF (@total = 0)
    PRINT 'No sessions owned by user ' + '[' + @login + ']';
于 2008-12-15T12:13:06.870 に答える
3

接続を手動で強制終了する以外に、次のことができます

  • 接続を廃棄します。つまり、何らかの方法で Connection オブジェクトを取得し、それらに対して .Close および .Dispose() を呼び出します。自動的に .Dispose() を呼び出すので、「using」を使用するのが理想的です。
  • アプリケーション プールをリサイクルします。
于 2008-12-15T11:13:18.830 に答える
3

sysprocesses の last_batch 列を使用して、実際にアクティブかどうかを判断します。SPID > 50 (または >= 50?) システム SPID の強制終了を回避します。

これをあなたの希望する睡眠時間と比較してください。

ループする必要があります。

DECLARE @kill_id smallint 
DECLARE spid_cursor CURSOR FOR
select spid from sysprocesses 
where dbid = > 4 and last_batch < dateadd(hour, -24, getdate()) and spid >= 50

OPEN spid_cursor

FETCH NEXT FROM spid_cursor INTO @kill_id

WHILE (@@FETCH_STATUS = 0)
BEGIN
-- Kill the current spid here
-- KILL @kill_id <---This line will not work

-- Get the next cursor row
FETCH NEXT FROM spid_cursor INTO @kill_id
END 

CLOSE spid_cursor

DEALLOCATE spid_cursor
于 2008-12-15T11:15:48.170 に答える
2

最初にこれを実行して、問題のあるデータベースを見つけます.....

SELECT DB_NAME(dbid) as 'Database Name', 
COUNT(dbid) as 'Total Connections' 
FROM master.dbo.sysprocesses WITH (nolock)
WHERE dbid > 0
GROUP BY dbid
SELECT @@MAX_CONNECTIONS AS 'Max Allowed Connections'

次に、これを実行して、目的の DB への接続を強制終了します

USE master
go

DECLARE @dbname sysname

SET @dbname = 'Events'

DECLARE @spid int
SELECT @spid = min(spid) from master.dbo.sysprocesses where dbid = db_id(@dbname)
WHILE @spid IS NOT NULL
BEGIN
EXECUTE ('KILL ' + @spid)
SELECT @spid = min(spid) from master.dbo.sysprocesses where dbid = db_id(@dbname) AND spid > @spid
END
于 2009-03-20T21:28:57.070 に答える