0

がわかりませんenvi_setup_head。IDLコード形式で書くのを手伝ってくれる人はいますか?

IDL で作成されたマップがあり、ENVI で処理する必要があります。画像をフォルダに保存して ENVI で開く方法がわかりません。誰もそれを行う方法を知っていますか?

4

1 に答える 1

0

画像ファイルの ENVI ヘッダーを作成するには、以下の IDL 手順のようなものを試すことができます。小さな画像ファイルenvi_setup_headを作成し、ENVI ヘッダー ファイルの作成に使用します。基本的に、サンプル数、行数、データ型などを指定するだけで、準備完了です。

pro enviHeaderTest
    compile_opt idl2

    ; Create the data and write to a file.
    ns = 100
    nl = 100
    data = dist(ns, nl)
    fname = 'mydatafile.dat'
    openw, lun, fname, /GET_LUN
    writeu, lun, data
    close, lun

    ; Open a headless ENVI.
    nv = envi(/HEADLESS)

    ; Create some map info for the raster.
    mc = [0,0,0,0] ;Tie point: [x pixel, ypixel, x map, y map]
    ps = [1D/3600, 1D/3600] ; Pixel size
    mapInfo = envi_map_info_create(/GEOGRAPHIC, MC=mc, PS=ps)

    ; Create the header.
    envi_setup_head, FNAME=fname, $ ; file name
        NS=ns, $                    ; number of samples
        NL=nl, $                    ; number of lines
        NB=1, $                     ; number of bands
        DATA_TYPE=4, $              ; IDL data type (float in this case)
        INTERLEAVE=0, $             ; BSQ
        MAP_INFO=mapInfo, $
        /WRITE

    ; Close ENVI.
    nv.close
end

次に、[File]->[Open] メニューから、または次のような IDL コマンド ラインを介して、イメージを ENVI に読み込むことができます。

IDL> nv = envi()
ENVI> view = nv.getview()
ENVI> raster = nv.openraster('mydatafile.dat')
ENVI> layer = view.createlayer(raster)
于 2016-05-25T23:50:55.040 に答える