-1

コードに次のエラーがありました。助けてください。命令は、0x00400014 [0x00400014] 0x0c000000 jal 0x00000000 [main] で未定義のシンボルを参照しています。188: jal main このコードは、華氏を摂氏に、摂氏を華氏に変換します 

.data 0x10008000

.word 5,9,32

 message1: 
    .asciiz "Select the temparature scale:<C or F><ENTER"
 message2: .asciiz "Type the desired temperature <ENTER>"
 message3: asciiz  "Temparature= "

.text

.globl main

main:
   li $v0,4
   la $a0,message1
   syscall

  li $v0,12
  syscall

  move $t0,$v0

  li $t1,70
  li$t2,67
 beq $t0,$t1,Farenheit
 beq $t0,$t2,Celcius

li $v0,10
 syscall


Farenheit:

     li $v0,4
     la $a0,message2
     syscall


     li $v0,6
     syscall

     lui $gp, 0x1000   #I put in register $gp the number 0x10008000,which                
     ori $gp, $gp,0x8000 # shows in the middle of address of static data

     lwc1 $f16, 0($gp)   

     cvt.s.w $f16, $f16



      lwc1 $f18, 4($gp)

     cvt.s.w $f18, $f18


      div.s $f20 , $f16,f$18

      lwc1 $f14, 8($gp)

      cvt.s.w $f14 $f14

      lwc1 $f12,$v0

      sub.s $f12,$f12,$f14

      mul.s $f0,$f20,$f12


       la $a0,message3
       li $v0,4
       syscall

      mov.s $f12,$f0
      li $v0,2
      syscall


       jr $ra


Celcius: 

     li $v0,4
     la $a0,message2
     syscall


     li $v0,6
     syscall

     lui $gp, 0x100
     ori $gp, $gp,0x8000

     lwc1 $f16, 0($gp)

     cvt.s.w $f16, $f16



      lwc1 $f18, 4($gp)

     cvt.s.w $f18, $f18


      div.s $f20 , $f18,f$16

      lwc1 $f14, 8($gp)

      cvt.s.w $f14 $f14

      lwc1 $f12,$v0

      mul.s $f12,$f12,$f20
      add.s $f0,$f12,$f14

       la $a0,message3
       li $v0,4
       syscall

      mov.s $f12,$f0
      li $v0,2
      syscall


       jr $ra
4

4 に答える 4

3

あなたのコードはきれいに組み立てることさえできません。

$gp[ハードコードされたオフセットで] を使用して にアクセスするのは.word 5,9,32やり過ぎでした。セクションに明示的なアドレスを設定する.dataこともおそらく良くありませんでした。

「read float」システムコールは値を$f0返します $v0

統合可能な摂氏セクションと華氏セクションの間には、多くの複製コードがありました。

jr $ra実際に計算セクションを呼び出すことなく [return from function] を使用していましたjal

ロジックの流れを説明するコメントがもっとあるはずです。ここで私の答えを見たいと思うかもしれません: MIPS のリンクされたリストには、asm スタイルとクリーンなコーディングのためのヒントがいくつかあります。

とにかく、クリーンアップされ、注釈が付けられ、機能するコードは次のとおりです。

    .data

temp5:      .word       5
temp9:      .word       9
temp32:     .word       32

msg_scale:  .asciiz     "Select the temperature scale:<C or F><ENTER>"
msg_temp:   .asciiz     "Type the desired temperature <ENTER>"
msg_out:    .asciiz     "Temperature= "
msg_nl:     .asciiz     "\n"

    .text

    .globl  main

main:
    # prompt user for temp type/scale
    li      $v0,4
    la      $a0,msg_scale
    syscall

    # read in temp scale
    li      $v0,12
    syscall
    move    $t0,$v0

    # output a newline
    la      $a0,msg_nl
    li      $v0,4
    syscall

    # prompt for temperature
    li      $v0,4
    la      $a0,msg_temp
    syscall

    # read in temperature
    # NOTE: result comes back in $f0 and _not_ $v0
    li      $v0,6
    syscall
    ###lwc1 $f12,$v0
    mov.s   $f12,$f0

    lwc1    $f16,temp5              # get 5
    cvt.s.w $f16,$f16

    lwc1    $f18,temp9              # get 9
    cvt.s.w $f18,$f18

    lwc1    $f14,temp32             # get 32
    cvt.s.w $f14,$f14

    # do fahrenheit to celcius
    li      $t1,'F'
    beq     $t0,$t1,Farenheit
    li      $t1,'f'
    beq     $t0,$t1,Farenheit

    # do celcius to fahrenheit
    li      $t1,'C'
    beq     $t0,$t1,Celcius
    li      $t1,'c'
    beq     $t0,$t1,Celcius

    j       main_exit

    # print results
main_print:
    la      $a0,msg_out
    li      $v0,4
    syscall

    mov.s   $f12,$f0
    li      $v0,2
    syscall

    la      $a0,msg_nl
    li      $v0,4
    syscall

    j       main

main_exit:
    li      $v0,10
    syscall

Farenheit:
    div.s   $f20,$f16,$f18          # get 5/9
    sub.s   $f12,$f12,$f14          # subtract 32 from temp
    mul.s   $f0,$f20,$f12           # multiply by 5/9
    j       main_print

Celcius:
    div.s   $f20,$f18,$f16          # get 9/5
    mul.s   $f12,$f12,$f20          # multiply by 9/5
    add.s   $f0,$f12,$f14           # add 32
    j       main_print
于 2016-05-06T03:10:03.523 に答える
0

私は私の大学のために同じエッセイを持っていました（あなたもAuthから来ているかもしれません。そうでなければ、このブラケットに意味がありません：P）

Craigs の返信で問題に対する回答が得られなかった場合は、正常に動作する私のコードを参照してください。

調査の結果 ( MIPS $gp レジスター およびインターネット経由)、gp を使用して静的データ セグメントに格納されたデータにアクセスするのは良い方法ではないと思いますが、それがプログラムが実行されるように指示された方法です!

また、シミュレーターを再初期化しないと、多くのエラーが発生する可能性があります。

ここに私のコードがあります。

 .data 0x10008000  
 .word 5, 9, 32
      message1: .asciiz "Select the temparature scale:<C or F>:"
      message2: .asciiz "Type the desired temperature:"
      message3: .asciiz  "Temparature= "
      newline:  .asciiz "\n" 
.text

.globl main

main:

li $v0,4
la $a0,message1
syscall                             #prompt message

#read the character
li $v0,12
syscall

move $t0,$v0

#check the character and branch                                     
li $t1,'F'
beq $t0,$t1,Fahrenheit             
li $t1,'f'
beq $t0,$t1,Fahrenheit             #fahrenheit to celsius

li      $t1,'C'
beq     $t0,$t1,Celsius
li      $t1,'c'
beq     $t0,$t1,Celsius            #celsius to fahrenheit

li $v0,10
syscall                            #end program

Fahrenheit:

li $v0,4
la $a0,newline
syscall                           #type new line


li $v0,4                          #type message 2
la $a0,message2
syscall             

li $v0,6
syscall                          #read float from user

#gp has 0x10008000 
lui $gp, 0x1000
ori $gp, $gp, 0x8000              #load to f16 number 5

lwc1 $f16, 0($gp)                

cvt.s.w $f16, $f16                #convert to float

lwc1 $f18, 4($gp)                 #load number 9 to f18

cvt.s.w $f18, $f18                #convert to float


div.s $f20, $f16, $f18            #divide 5/9 and save it to f20

lwc1 $f14, 8($gp)                 #load number 32

cvt.s.w $f14, $f14                #convert to float


li      $v0,6                     #read from user float
mov.s   $f12,$f0                 

sub.s $f12, $f12, $f14            #Fahrenheit - 32

mul.s $f0, $f20, $f12             #(Fahrenheit-32)*5/9 ,the result

li $v0,4
la $a0,newline
syscall                           #type new line

li $v0,4
la $a0,message3
syscall                           #type message 3

mov.s   $f12,$f0
li      $v0,2
syscall                           #type the result

jr $ra

Celsius: 
li $v0,4
la $a0,newline
syscall                          #type new line


li $v0,4                         #type message 2
la $a0,message2
syscall             

li $v0,6
syscall                          #read float from user

lui $gp, 0x1000
ori $gp, $gp,0x8000

lwc1 $f16, 0($gp)                 #load number 5 to f16

cvt.s.w $f16, $f16                #convert to float

lwc1 $f18, 4($gp)                 #load number 9 to f18

cvt.s.w $f18, $f18                #convert to float

div.s $f20 , $f18,$f16            #save number 9/5( f18 / f16) to f20

lwc1 $f14, 8($gp)                 #load number 32 to f14

cvt.s.w $f14 $f14                 #convert to float

li      $v0,6                     #read from user
mov.s   $f12,$f0

mul.s $f0,$f12,$f20               #Celsius * 9/5
add.s $f0,$f0,$f14                #(Celsius*9/5)+32

li $v0,4
la $a0,message3
syscall                           #Type the Result!

mov.s   $f12,$f0
li      $v0,2
syscall

jr $ra
于 2016-05-10T21:48:28.230 に答える
-1

@kintzo やあKintzo、私は auth 出身です。あなたの助けに感謝します.私はすでに私のコードを実行しました.それはあなたのものと非常に似ています.しかし、私は2つの機能を実行しました. $jal 経由。これは Craig によって言及されていた問題です。私のコードは次のとおりです。

.data 0x10008000
     .word       5,9,32



msg_scale:  .asciiz     "Select the temperature scale:<C or F><ENTER>"
msg_temp:   .asciiz     "Type the desired temperature <ENTER>"
msg_out:    .asciiz     "Temperature= "
msg_nl:     .asciiz     "\n"

    .text

    .globl  main

main:
    # prompt user for temp type/scale
    li      $v0,4
    la      $a0,msg_scale
    syscall






  # read in temp scale
    li      $v0,12
    syscall
    move    $t0,$v0

    # output a newline
    la      $a0,msg_nl
    li      $v0,4
    syscall

    # prompt for temperature
    li      $v0,4
    la      $a0,msg_temp
    syscall

    # read in temperature
    # NOTE: result comes back in $f0 and _not_ $v0
    li      $v0,6
    syscall



    li      $t1,'F'
    beq     $t0,$t1,F


    li      $t1,'C'
    beq     $t0,$t1,C

 F: 
        jal Farenheit

    la      $a0,msg_out
    li      $v0,4
    syscall

    mov.s   $f12,$f0
    li      $v0,2
    syscall

    la      $a0,msg_nl
    li      $v0,4
    syscall


   j       main_exit


 C:
        jal Celcius


    la      $a0,msg_out
    li      $v0,4
    syscall

    mov.s   $f12,$f0
    li      $v0,2
    syscall

    la      $a0,msg_nl
    li      $v0,4
    syscall


j       main_exit



main_exit:
    li      $v0,10
    syscall





  .globl Farenheit 

   Farenheit:

    lui $gp , 0x1000
    ori $gp , $gp, 0x8000

     lwc1 $f16 , 0($gp)

     cvt.s.w $f16,$f16

    lwc1 $f18, 4($gp)

    cvt.s.w $f18, $f18

    lwc1 $f14, 8($gp)

    cvt.s.w $f14 $f14

    div.s   $f20,$f16,$f18          # get 5/9
    mov.s   $f12,$f0
    sub.s   $f12,$f12,$f14          # subtract 32 from given temprerature
    mul.s   $f0,$f20,$f12           # multiply by 5/9
    jr      $ra







 .globl Celcius 

  Celcius:

    lui $gp , 0x1000
    ori $gp , $gp, 0x8000

     lwc1 $f16 , 0($gp)

     cvt.s.w $f16,$f16

    lwc1 $f18, 4($gp)

    cvt.s.w $f18, $f18

    lwc1 $f14, 8($gp)

    cvt.s.w $f14 $f14


    div.s   $f20,$f18,$f16          # get 9/5
    mov.s   $f12,$f0
    mul.s   $f12,$f12,$f20          # multiply by 9/5
    add.s   $f0,$f12,$f14           # add 32
    jr      $ra
于 2016-05-15T12:00:30.620 に答える