string - 文字列からのgnuplotプロット

Question

文字列でプロットデータに渡すことは可能ですか？

つまり、次のようなことをします。

plot "09-13-2010,2263.80 09-14-2010,2500" using 1:2 with lines

Answer 1

次のようなことを行うことができます。

set xdata time
set timefmt "%m-%d-%y"     
plot "< echo '09-13-2010,2263.80 09-14-2010,2500' | tr ' ' '\n' | tr ',' ' '" using 1:2 with lines

<コマンドの出力からの入力が必要であることを文字がGnuplotに示している場合。gnuplotはレコードを改行で区切ります。レコードのグループは、空白のレコードで区切られます。レコード内では、デフォルトの列区切り文字はスペースです。上記の例trでは、データを行に分割し、行をレコードに書き換えるために使用されています。

文字列からデータをプロットする別の方法は、「-」入力指定子を使用して、コマンドラインからデータをロードすることです。プログラムは簡単に次のものを放出する可能性があります。

set xdata time
set timefmt "%m-%d-%y"
plot '-' using 1:2 with lines
09-13-2010 2263.80
09-14-2010 2500
e

最善の策は、次のような入力ファイルを使用することです。

09-13-2010 2263.80
09-14-2010 2500

入力ファイルの名前がmydata.txt、であるとすると、次のコマンドを使用してプロットできます。

set xdata time
set timefmt "%m-%d-%y"
plot 'mydata.txt' using 1:2 with lines

上記のすべての例では、次のようなものが得られます。

日付と「-」入力を使用して2つのデータ系列をプロットする場合は、次のようにすることができます。

set xdata time
set timefmt "%m-%d-%y"
plot '-' using 1:2  title "Series 1" with lines,'-' using 1:2 title "Series 2" with lines
09-13-2010 2263.80
09-14-2010 2500
e
09-13-2010 2500
09-14-2010 2263.80
e

前の例では、次のようになります。