intellij-idea - kotlin ライブラリ (Android ではない) を jCenter に公開する

Question

Kotlinで書かれたIntellij Idea 2016.1 gradle-application(Androidではない)があります。jCenter に配置し、依存関係として Android アプリケーションに追加する必要があります。私はそれに関する情報を見つけることができません。すべての参照は、Android プロジェクトを参照しています。これがどのように行われるかについての概念はありません。詳細な指示を探しています

Answer 1

Kotlin ライブラリを jCenter に公開する方法は、Java ライブラリの場合とまったく同じです。

buildscript {
  ext.kotlinVersion = '1.0.2'

  repositories {
    mavenCentral()
  }

  dependencies {
    classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
  }
}

plugins {
  id "com.jfrog.bintray" version "1.6"
}

apply plugin: 'kotlin'
apply plugin: 'maven-publish'

group '<groupId>'
version '<version>'
sourceCompatibility = 1.6

repositories {
  mavenCentral()
}

dependencies {
  compile "org.jetbrains.kotlin:kotlin-stdlib:$kotlinVersion"
}

bintray {
  user = '<bintray user name>'
  key = '<bintray API key>'
  publications = ['mavenJava']

  pkg {
    repo = '<repository name on bintray>'
    name = '<artifactId>'

    version {
      name = project.version
      released = new Date()
      vcsTag = "v${project.version}"
    }
  }
}

task sourcesJar(type: Jar, dependsOn: project.classes) {
  from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: project.javadoc) {
  from javadoc.destinationDir
}

artifacts {
  archives sourcesJar, javadocJar
}

publishing {
  publications {
    mavenJava(MavenPublication) {
      artifactId project.bintray.pkg.name
      from components.java

      artifact sourcesJar {
        classifier = 'sources'
      }
      artifact javadocJar {
        classifier = 'javadoc'
      }
    }
  }
}

bintray にリポジトリを作成し、 を呼び出すだけ./gradlew bintrayUploadです。アップロードされた依存関係を公開するよう bintray プラグインに要求しない場合は、bintray アカウントから手動で公開する必要があります。

依存関係が公開されると、アカウントからリンクできjCenterます。公開された後jCenterは、Android プロジェクトからの通常の依存関係として使用できます。