3

xml をアルファベット順に並べ替える次の xsl があります。

<xsl:template match="/">
  <xsl:apply-templates />
</xsl:template> 

<xsl:key name="rows-by-title" match="Row" use="translate(substring(@Title,1,1),'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ')" />
<xsl:variable name="StartRow" select="string('&lt;tr &gt;')" />

<xsl:template name="Meunchian" match="/dsQueryResponse/Rows">
  <table>
    <tr>
      <xsl:for-each select="Row[count(. | key('rows-by-title', translate(substring(@Title,1,1),'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ'))[1]) = 1]">
        <xsl:sort select="translate(substring(@Title,1,1),'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ')" />
        <!-- Puts out the title -->
        <td>
          <xsl:value-of select="translate(substring(@Title,1,1),'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ')" />
        </td>
        <!-- Now all it's children -->
        <xsl:for-each select="key('rows-by-title', translate(substring(@Title,1,1),'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ'))">
          <xsl:value-of select="@Title" /><br/>
        </xsl:for-each>
      </xsl:for-each>
   </tr>
  </table>
</xsl:template>

XML:

<dsQueryResponse>
  <Rows>
    <Row Title="Agenda" />
    <Row Title="Policy" />
    <Row Title="Policy" />
    <Row Title="Report" />
    <Row Title="Report" />
  </Rows>
</dsQueryResponse>

出力が次のようになるように、出力される 4 列ごとにテーブル行を分割したいと考えています。

ABCD
EFGH
IJKL
MNOP
QRST
UVWX
YZ

誰でもこれを達成するための最良の方法を提案できますか?

どうもありがとう

4

4 に答える 4

3

これが私の解決策です。

パラメータを使用して、空のセルを表示するか非表示にするかを決定でき"per-row"ます"show-empty"。もっとエレガントなバージョンが存在すると確信していますが、思いつきませんでした。;-) コメント歓迎。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="html" version="4.0" encoding="iso-8859-1" indent="yes"/>

  <xsl:key name="rows-by-title" match="Row" use="translate(substring(@Title, 1, 1), 'abcdefghijklmnopqrstuvwxyz', 'ABCDEFGHIJKLMNOPQRSTUVWXYZ')" />
  <xsl:variable name="alphabet" select="string('ABCDEFGHIJKLMNOPQRSTUVWXYZ')" />
  <xsl:variable name="per-row" select="number(4)" /> 
  <xsl:variable name="show-empty" select="false()" />

  <xsl:template match="/">
    <xsl:apply-templates select="dsQueryResponse/Rows" />
  </xsl:template> 

  <xsl:template match="Rows">
    <table>
      <xsl:call-template name="create-rows" />
    </table>
  </xsl:template>

  <xsl:template name="create-rows">
    <xsl:param name="index" select="1" />

    <xsl:variable name="letters">
      <xsl:call-template name="next-letters">
        <xsl:with-param name="index" select="$index" />
      </xsl:call-template>
    </xsl:variable>

    <xsl:if test="$letters != ''">
      <tr title="{$letters}">
        <xsl:call-template name="create-cells">
          <xsl:with-param name="letters" select="$letters" />
        </xsl:call-template>
      </tr>
    </xsl:if>

    <xsl:if test="string-length($letters) = $per-row">
      <xsl:call-template name="create-rows">
        <xsl:with-param name="index" select="string-length(substring-before($alphabet, substring($letters, string-length($letters), 1))) + 2" />
      </xsl:call-template>
    </xsl:if>
  </xsl:template>

  <xsl:template name="next-letters">
    <xsl:param name="index" />

    <xsl:variable name="letter" select="substring($alphabet, $index, 1)" />

    <xsl:variable name="letters">
      <xsl:if test="$index &lt;= string-length($alphabet)">
        <xsl:if test="$show-empty or key('rows-by-title', $letter)">
          <xsl:value-of select="$letter" />
        </xsl:if>

        <xsl:call-template name="next-letters">
          <xsl:with-param name="index" select="$index + 1" />
        </xsl:call-template>
      </xsl:if>
    </xsl:variable>

    <xsl:value-of select="substring($letters, 1, $per-row)" />
  </xsl:template>

  <xsl:template name="create-cells">
    <xsl:param name="letters" />

    <xsl:variable name="letter" select="substring($letters, 1, 1)" />

    <xsl:if test="$letter != ''">
      <td title="{$letter}">
        <strong>
          <xsl:value-of select="$letter" />
        </strong>
        <xsl:apply-templates select="key('rows-by-title', $letter)">
          <xsl:sort select="@Title" />
        </xsl:apply-templates>
      </td>
      <xsl:call-template name="create-cells">
        <xsl:with-param name="letters" select="substring($letters, 2, string-length($letters) - 1)" />
      </xsl:call-template>
    </xsl:if>
  </xsl:template>

  <xsl:template match="Row">
    <br />
    <xsl:value-of select="@Title" />
  </xsl:template>

</xsl:stylesheet>

この入力で：

<dsQueryResponse>
  <Rows>
    <Row Title="Agenda" />
    <Row Title="Policy" />
    <Row Title="Policy" />
    <Row Title="Report" />
    <Row Title="Report" />
    <Row Title="Test2" />
    <Row Title="Test1" />
    <Row Title="Boo" />
    <Row Title="Foo" />
  </Rows>
</dsQueryResponse>

この出力が生成されます (title属性はデバッグ用です。私はそれらをそのままにして、いつでも削除します):

<table>
  <tr title="ABFP">
    <td title="A">
      <strong>A</strong>
      <br>Agenda
    </td>
    <td title="B">
      <strong>B</strong>
      <br>Boo
    </td>
    <td title="F">
      <strong>F</strong>
      <br>Foo
    </td>
    <td title="P">
      <strong>P</strong>
      <br>Policy
      <br>Policy
    </td>
  </tr>
  <tr title="RT">
    <td title="R">
      <strong>R</strong>
      <br>Report
      <br>Report
    </td>
    <td title="T">
      <strong>T</strong>
      <br>Test1
      <br>Test2
    </td>
  </tr>
</table>
于 2008-12-19T11:44:16.343 に答える
1

この質問は、問題が実際に何であるかを誰でも理解できるように編集する必要があります。Tomalak によるコメントは、OP が「アルファベット順に並べられたグリッド内のアイテムのリストを必要としている」ことを明らかにしています。

次の変換:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
 extension-element-prefixes="ext"
 >

 <xsl:variable name="vDoc" select="/"/>
 <xsl:variable name="vNumCols" select="4"/>

 <xsl:variable name="vLower"
  select="'abcdefghijklmnopqrstuvwxyz'"
  />

 <xsl:variable name="vUpper"
  select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"
  />

  <xsl:key name="rows-by-FirstLetter" match="Row"
  use="translate(substring(@Title,1,1),
                 'abcdefghijklmnopqrstuvwxyz',
                 'ABCDEFGHIJKLMNOPQRSTUVWXYZ')" />

  <xsl:variable name="vrtfStartLetters">
    <xsl:for-each select=
    "/*/*/Row
           [count(.
               |
                key('rows-by-FirstLetter',
                   translate(substring(@Title,1,1),
                             $vLower,
                             $vUpper)
                  )[1]
                  )
              = 1
           ]">

         <startLetter>
           <xsl:value-of select=
             "translate(substring(@Title,1,1),
                      $vLower,
                      $vUpper)"/>
         </startLetter>
      </xsl:for-each>
    </xsl:variable>

    <xsl:variable name="vStartLetters" select=
      "ext:node-set($vrtfStartLetters)"/>

  <xsl:template match="Rows">
    <table>
      <xsl:apply-templates select=
       "$vStartLetters/*[position() mod $vNumCols = 1]">
        <xsl:with-param name="pDoc" select="$vDoc"/>
        <xsl:with-param name="pNumCols" select="$vNumCols"/>
      </xsl:apply-templates>
    </table>
  </xsl:template>

  <xsl:template match="startLetter">
    <xsl:param name="pDoc"/>
    <xsl:param name="pNumCols" select="10"/>
    <tr>
      <xsl:apply-templates mode="copy" select=
      ". | following-sibling::*
               [not(position() >= $pNumCols)]">
         <xsl:with-param name="pDoc" select="$pDoc"/>
         <xsl:sort/>

      </xsl:apply-templates>
    </tr>
  </xsl:template>

  <xsl:template match="startLetter" mode="copy">
    <xsl:param name="pDoc"/>

    <xsl:variable name="pThis" select="."/>

    <td>
      <xsl:value-of select="."/>
      <br />
      <table>
     <xsl:for-each select="$pDoc">
      <xsl:for-each select="key('rows-by-FirstLetter', $pThis)">
        <tr><td><xsl:value-of select="@Title"/></td></tr>
      </xsl:for-each>
     </xsl:for-each>
    </table>
    </td>
  </xsl:template>
</xsl:stylesheet>

この XML ドキュメントに適用した場合:

<dsQueryResponse>
  <Rows>
    <Row Title="Agenda" />
    <Row Title="Accrual" />
    <Row Title="Ads" />
    <Row Title="Averages" />
    <Row Title="Bindings" />
    <Row Title="Budget" />
    <Row Title="Cars" />
    <Row Title="Categories" />
    <Row Title="Costs" />
    <Row Title="Policy" />
    <Row Title="Politics" />
    <Row Title="Reevaluations" />
    <Row Title="Report" />
  </Rows>
</dsQueryResponse>

必要な結果を生成します：

<table>
  <tr>
    <td>A
      <br/>
      <table>
        <tr>
          <td>Agenda</td>
        </tr>
        <tr>
          <td>Accrual</td>
        </tr>
        <tr>
          <td>Ads</td>
        </tr>
        <tr>
          <td>Averages</td>
        </tr>
      </table>
    </td>
    <td>B
      <br/>
      <table>
        <tr>
          <td>Bindings</td>
        </tr>
        <tr>
          <td>Budget</td>
        </tr>
      </table>
    </td>
    <td>C
      <br/>
      <table>
        <tr>
          <td>Cars</td>
        </tr>
        <tr>
          <td>Categories</td>
        </tr>
        <tr>
          <td>Costs</td>
        </tr>
      </table>
    </td>
    <td>P
      <br/>
      <table>
        <tr>
          <td>Policy</td>
        </tr>
        <tr>
          <td>Politics</td>
        </tr>
      </table>
    </td>
  </tr>
  <tr>
    <td>R
      <br/>
      <table>
        <tr>
          <td>Reevaluations</td>
        </tr>
        <tr>
          <td>Report</td>
        </tr>
      </table>
    </td>
  </tr>
</table>

次の 3 つの点に注意してください。

  • ( exslt ) ext:node-set()拡張関数を使用して、中間結果を RTF (Result-Tree Fragment) から一時ツリーに変換しています。

  • 元の<xsl:for-each select="$pDoc">XML ドキュメントを現在の XML ドキュメントに戻す必要があります。これにより、key() 関数は、一時ツリーではなく、このドキュメント用に作成されたインデックスを使用します。

  • (4) 開始文字の新しい行を開始する必要がある各開始文字は、特別なテンプレートで処理され、その中で<tr>が作成されます。次に、これと行の残りの (3) 文字の開始文字が、<tr>「コピー」モードの本体内で処理され、<td>それぞれが作成されます。

ここでは、いくつかの高度な XSLT 手法について説明し、実演しました。

  • mod数量でグループ化するための演算子の使用。
  • 現在のドキュメントとは異なるドキュメントに対してkey()関数を使用する。
  • モード
  • RTFを一時ツリーに変換する

お楽しみください:)

于 2008-12-19T16:19:01.953 に答える
0

これは、拡張機能を必要としない 2 番目のソリューションです。これは再帰的ではなく、再帰的よりも効率的である可能性があることに注意してください。

この変換:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:namespace"
 exclude-result-prefixes="my"
 >
 <xsl:出力方法="html"/>

  <my:alpha>
    <l>A</l><l>B</l><l>C</l><l>D</l><l>E</l>
    <l>F</l><l>G</l><l>H</l><l>I</l><l>J</l>
    <l>K</l><l>L</l><l>M</l><l>N</l><l>O</l>
    <l>P</l><l>Q</l><l>R</l><l>S</l><l>T</l>
    <l>U</l><l>V</l><l>W</l><l>X</l><l>Y</l>
    <l>Z</l>
  </my:アルファ>
    <xsl:variable name="vDoc" select="/"/>
    <xsl:variable name="vNumCols" select="4"/>
    <xsl:変数名="vLower" select="'abcdefghijklmnopqrstuvwxyz'" />
    <xsl:変数名="vUpper" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'" />

    <xsl:key name="rows-by-FirstLetter" match="Row"
      use="translate(substring(@Title,1,1),
                     'abcdefghijklmnopqrstuvwxyz',
                     'ABCDEFGHIJKLMNOPQRSTUVWXYZ')" />

  <xsl:変数名="vStartingLetters">
    <xsl:for-each select=
        "/*/*/行
           [生成-id()
           =
            generate-id(key('rows-by-FirstLetter',
                             translate(substring(@Title,1,1),
                                                 $vLower、
                                                 $vUpper)
                             )[1]
                         )
            ]">
      <xsl:selectの値=
         "translate(substring(@Title,1,1),
                    $vLower、
                    $vUpper)"/>
    </xsl:for-each>
  </xsl:変数>

  <xsl:変数名="vMyLetters" select=
   "document('')/*/my:alpha/l[contains($vStartingLetters,.)]"
   />

    <xsl:template match="行">
        <テーブル>
          <xsl:for-each select=
            "$vMyLetters[position() mod $vNumCols = 1]">
            <xsl:変数名="vPos"
               select="(position()-1)*$vNumCols+1"/>

              <tr>
                 <xsl:apply-templates select=
                  "$vMyLetters[位置() >= $vPos
                              と
                               not(position() > $vPos+$vNumCols -1)
                              ]">
            <xsl:with-param name="pDoc" select="$vDoc"/>
                 </xsl:適用-テンプレート>
              </tr>
             </xsl:for-each>
        </表>
    </xsl:テンプレート>

    <xsl:template match="l">
        <xsl:param name="pDoc"/>

        <xsl:変数名="pThis" select="."/>

        <td>
            <xsl:value-of select="."/>
            <br />
            <テーブル>
                <xsl:for-each select="$pDoc">
                    <xsl:for-each select=
                            "key('rows-by-FirstLetter', $pThis)">
                <tr>
                  <td>

                    <xsl:value-of select="@Title"/>
                  </td>
                </tr>
                    </xsl:for-each>
                </xsl:for-each>
            </表>
        </td>
    </xsl:テンプレート>
</xsl:スタイルシート>

次の XML ドキュメントに適用した場合:

<dsQueryResponse>
    <行>
        <Row Title="アジェンダ" />
        <行のタイトル="ポリシー" />
        <行のタイトル="ポリシー" />
        <Row Title="レポート" />
        <Row Title="レポート" />
        <行のタイトル="Test2" />
        <行のタイトル="Test1" />
        <行のタイトル="ブー" />
        <行のタイトル="フー" />
    </行>
</dsQueryResponse>

必要な結果が生成されます。

<テーブル>
   <tr>
      <td>A<br><表>
            <tr>
               <td>議題</td>
            </tr>
         </表>
      </td>
      <td>B<br><表>
            <tr>
               <td>ブー</td>
            </tr>
         </表>
      </td>
      <td>F<br><テーブル>
            <tr>
               <td>足</td>
            </tr>
         </表>
      </td>
      <td>P<br><表>
            <tr>
               <td>ポリシー</td>
            </tr>
            <tr>
               <td>ポリシー</td>
            </tr>
         </表>
      </td>
   </tr>
   <tr>
      <td>R<br><表>
            <tr>
               <td>報告</td>
            </tr>
            <tr>
               <td>報告</td>
            </tr>
         </表>
      </td>
      <td>T<br><テーブル>
            <tr>
               <td>テスト2</td>
            </tr>
            <tr>
               <td>テスト1</td>
            </tr>
         </表>
      </td>
   </tr>
</表>

ここではモードを使用しないという唯一の例外を除いて、最初の回答のほとんどの説明がこのソリューションにも適用されることに注意してください。

于 2008-12-20T03:10:14.180 に答える
-1

私は質問に少し混乱していますが、あなたが探しているのは、position（）とmodの組み合わせを使用したxsl：ifテストだと思います

于 2008-12-18T09:54:38.317 に答える