2

ANTLRWorks 1.4 で次のコードを記述しました。

grammar hmm;

s           :   (put_a_in_b)|(put_out_a)|(drop_kick)|(drop_a)|(put_on_a);

put_a_in_b  :   (PUT_SYN)(ID)(IN_SYN)(ID);  
put_out_a   :   (PUT2_SYN)(OUT_SYN)(ID) | (E1)(ID); 
drop_kick   :   ('drop')('kick')(ID);
drop_a      :   (DROP_SYN)(ID);
put_on_a    :   (E2)(ID);

PUT_SYN     :   'put' | 'place' | 'drop';
PUT2_SYN    :   'put' | 'douse';
IN_SYN      :   'in' | 'into' | 'inside' | 'within';    
OUT_SYN     :   'out';
E1          :   'extinguish'|'douse';
DROP_SYN    :   'drop' | 'throw' | 'relinquish';
WS          :   ( ' '  | '\t' | '\r' | '\n' ) {$channel=HIDDEN;};
ID          :   ('a'..'z'|'A'..'Z'|'_') ('a'..'z'|'A'..'Z'|'0'..'9'|'_')*;
E2          :   'put on'|'don'|'wear';
COMMENT
    :   '//' ~('\n'|'\r')* '\r'? '\n' {$channel=HIDDEN;}
    |   '/*' ( options {greedy=false;} : . )* '*/' {$channel=HIDDEN;}
    ;

入力で実行すると：

drop object

MismatchedTokenException(5 != 15) が発生します。

そして入力で：

put o1 in o2

NoViableAltException が発生します。

それはうまくいきますが

place o2 in o2

私はこれに慣れていませんが、あいまいさがあるようですか？それとも私のANTLRの使い方が間違っているのでしょうか?

4

1 に答える 1

2

'drop'および'put'を 2 つの異なるレクサー ルールに入れました。

PUT_SYN  : 'put' | 'place' | 'drop';          // drop & put
PUT2_SYN : 'put' | 'douse';                   //        put
...
DROP_SYN : 'drop' | 'throw' | 'relinquish';   // drop

putlexer が に遭遇すると、常にPUT_SYNそれに一致するルールになるため'put'、ルールから削除できます (または削除する必要があります) PUT2_SYN。

したがって、文字列drop objectの解析に関する問題：パーサーは一致しようとしますdrop_a : (DROP_SYN)(ID);が"drop"、レクサールールで一致しPUT_SYNます。

編集

これらのシノニム リストは、(レクサー ルールの代わりに) パーサー ルールにする方が適切です。ここに小さなデモがあります：

grammar TextAdventure;

parse
  :  command (EndCommand command)* EOF
  ;

command
  :  put_syn_1 OtherWord in_syn OtherWord
  |  put_syn_2 out_syn_1 OtherWord
  |  out_syn_2 OtherWord
  |  Drop Kick OtherWord
  |  drop_syn OtherWord
  ;

drop_syn
  :  Drop
  |  Throw 
  |  Relinquish
  ;

in_syn
  :  In
  |  Into
  |  Inside
  |  Within
  ; 

put_syn_1
  :  Put
  |  Place
  |  Drop
  ;

put_syn_2
  :  Put
  |  Douse
  ;

out_syn_1
  :  Out
  ;

out_syn_2
  :  Extinguish
  |  Douse
  ;

Space      : (' ' | '\t' | '\r' | '\n'){$channel=HIDDEN;};
EndCommand : ';';
Put        : 'put';
Place      : 'place';
Drop       : 'drop';
Douse      : 'douse';
In         : 'in';
Into       : 'into';
Inside     : 'inside';
Within     : 'within';    
Out        : 'out';
Extinguish : 'extinguish';
Throw      : 'throw';
Relinquish : 'relinquish';
Kick       : 'kick';
OtherWord  : ('a'..'z' | 'A'..'Z')+;

以下のソースを解釈すると：

drop object ; put yourself in myshoes ; place it in avase

ANTLRWorks が次の解析ツリーを生成することがわかります。

代替テキスト

于 2010-09-26T19:05:32.717 に答える