autoit - AutoIt：ControlTreeViewで要素のコンテキストメニューをアクティブにして選択します

Question

AutoItによる自動インストールをしたい。「機能の選択」ステップで要素メニューをアクティブにして選択できません。「ツリー」内の任意の要素を選択できます。そのために私は関数を使用します

ControlTreeView($windowId, "", $h_tree, "Select", "#2")

ControlTreeViewで要素メニューをアクティブにして選択するにはどうすればよいですか？

Answer 1

あなたはキーボードでそれを行うことができます。

私は過去にこれを

send("{down}{space}{down}{down}{enter}")

組み合わせ。これが最善の方法ではないことはわかっていますが、機能します。

Answer 2

あなたはサイト http://forum.oszone.net/thread-146460.htmlで質問の答えを見ることができます

#include <GuiMenu.au3>
#include <GuiTreeView.au3>
#Include <SendMessage.au3>
#Include <WindowsConstants.au3>

$WinTitle= "1С:Предприятие 8.1"
$WinText = "Выберите компоненты программы"

WinWait($WinTitle, $WinText)
; ищем элемент окна и последовательно нужный пункт списка
$hDTCtrl = ControlGetHandle($WinTitle, "", "SysTreeView321")
$hDTItem = _GUICtrlTreeView_FindItem($hDTCtrl, "Дополнительные интерфейсы")
$hDTIt_1 = _GUICtrlTreeView_FindItem($hDTCtrl, "Казахский", False, $hDTItem)
; активируем окно
WinActivate($WinTitle, $WinText)
WinWaitActive($WinTitle, $WinText)
; переходим к нужному пункту списка
_GUICtrlTreeView_SelectItem($hDTCtrl, $hDTIt_1, $TVGN_FIRSTVISIBLE)
_GUICtrlTreeView_ClickItem ($hDTCtrl, $hDTIt_1, "left", True)
; вызываем контекстное меню
$aRect = _GUICtrlTreeView_DisplayRect($hDTCtrl, $hDTIt_1, True)
ControlClick($WinTitle, $WinText, $hDTCtrl, "left", 1, $aRect[0]-10, $aRect[1]+5)
WinWait("[CLASS:#32768]")
; выбираем нужный пункт контекстного меню
$hWnd  = WinGetHandle("[CLASS:#32768]")
$hMenu = _SendMessage($hWnd, $MN_GETHMENU, 0, 0)
$aRect = _GUICtrlMenu_GetItemRect($hWnd, $hMenu, 0)
MouseClick("left", $aRect[0]+20, $aRect[1]+15, 1, 1)