0

私はScriptProcess、子プロセスへのインターフェースとして機能する、QML で使用することを意図した C++ クラスを作成しています。この子プロセスはスクリプトをロードし、オンデマンドで関数を実行します。関数を呼び出すと、結果 (値または例外) がシグナルを介して非同期に返されます。

import QtQuick 2.5
import QtTest 1.0
import dungeon 1.0

TestCase {
    id: test
    name: "ScriptProcessTest"

    property ScriptProcess session: null

    signal exceptionWhenLoadingCode(string type, int line, string message)

    SignalSpy {
        id: exceptionSpy
        target: test
        signalName: "exceptionWhenLoadingCode"
    }

    Component {
        id: process

        ScriptProcess {
            id: script

            onExceptionWhenLoadingCode: test.exceptionWhenLoadingCode(type, line, message)
        }
    }

    function startScript(scriptUrl) {
        var request = new XMLHttpRequest()
        request.open("GET", "data/%1.js".arg(scriptUrl), false)
        request.send(null)

        return process.createObject(test, {code: request.responseText})
    }

    function cleanup() {
        if (session) {
          session.stop()
        }

        delete session
        session = null
    }

    function test_syntaxErrorInGlobalContextIsReported() {
        var count = exceptionSpy.count
        session = startScript("syntax-error-in-global-context")

        compare(exceptionSpy.count, count + 1)
    }

    function test_errorThrownInGlobalContextIsReported() {
        var count = exceptionSpy.count
        session = startScript("error-in-global-context")

        compare(exceptionSpy.count, count + 1)
    }
}

一言で言えば、私は次のことを行います。

  1. テストごとに、補助プロセスを開き、ファイルからスクリプトをロードします。これはComponent、プロパティを介して指定されたスクリプトを使用して をインスタンス化することによって行われますScriptProcess.code。
  2. テストを実行します。
  3. テストが終了したら、プロセスを強制終了し、それを管理するオブジェクトを削除します。

私の問題は、SignalSpy呼び出されたexceptionSpyものがトリガーされていないことです。exceptionSpy.countは常にゼロであり、その理由はわかりません。 これはなぜですか？私は誤用していますSignalSpyかComponent？

4

1 に答える 1

1

XMLHttpRequest非同期なので、おそらくstartScript()次のように変更する必要があります。

function startScript(scriptUrl) {
    var object = process.createObject(test)

    var request = new XMLHttpRequest()
    request.onreadystatechange = function() {
        if (request.readyState === XMLHttpRequest.DONE)
            object.code = request.responseText
    }
    request.open("GET", "data/%1.js".arg(scriptUrl), false)
    request.send(null)

    return object
}

また、シグナルはすぐには送信されないため、オブジェクトを作成した直後にカウントを比較するのではなく、シグナルを待つ必要があります。

function test_foo() {
    var count = exceptionSpy.count
    session = startScript("...")

    tryCompare(exceptionSpy, "count", count + 1)
}
于 2016-08-11T03:37:39.527 に答える