1

私はgpathを使用してxmlを解析しています。stat オブジェクトから合格/不合格の値を取得したいと考えています。私が抱えていた問題は、オブジェクトがグループ化されていることです。個別にアクセスすることはできません。

これは私が扱っているデータです。

<robot>
<statistics>
  <total>
    <stat fail="28" pass="10">Critical Tests</stat>
    <stat fail="28" pass="10">All Tests</stat>
  </total>
</statistics>
</robot>

これらのオブジェクトでグルーヴィーが見ているものをチェックするとき

*印刷 (stats.size()) は 1 を返します

印刷 (stats.stat['@pass])は 1010 を返します

統計を明確にするために、レベルの gpath オブジェクトです。

2つの異なる「統計」を単純に連結しているように見えます

ありがとう！

編集：

ここに私が今持っているコードがあります。

def stats = robot.statistics.total
    println(stats.size())
    println(stats.stat['@pass'])
    for (int i = 0; i < stats.size(); i++) {
        println(stats[i].stat)
        if (stats[i].stat == "All Tests") {
            println('i am here')
            println(stats[i].stat['@pass'])
            int totalPass = stats[i].stat['@pass']
            int totalFail = stats[i].stat['@fail']
        }
    }
4

2 に答える 2

1

または、次のようにすることもできます。

def xmlText = """
<robot>
<statistics>
  <total>
    <stat fail="28" pass="10">Critical Tests</stat>
    <stat fail="28" pass="10">All Tests</stat>
  </total>
</statistics>
</robot>
"""

def xml = new XmlSlurper().parseText(xmlText)

def result = ['pass', 'fail'].collectEntries {
    [it, xml.statistics.total.stat.@"$it"*.text()*.asType(Integer).sum()]
}

assert result == [pass:20, fail:56]
于 2016-08-23T08:56:13.337 に答える
1

次の例を考えてみましょう: ノードを反復処理しますstat(そして合計を計算します):

def xml = """
<robot>
<statistics>
  <total>
    <stat fail="28" pass="10">Critical Tests</stat>
    <stat fail="28" pass="10">All Tests</stat>
  </total>
</statistics>
</robot>
"""

def robot = new XmlSlurper().parseText(xml)

int totalPass = 0
int totalFail = 0

robot.statistics.total.stat.each { statNode -> 
    println "processing: " + statNode.text()
    totalPass += (statNode.@'pass'.text() as int)
    totalFail += (statNode.@'fail'.text() as int) 
} 

println "totalPass: " + totalPass
println "totalFail: " + totalFail
于 2016-08-22T23:16:55.803 に答える