3

私が持っている 1 つの長期プロジェクトは、SICP のすべての演習に取り組んでいます。最近の演習で少し奇妙なことに気付きました。ハフマン エンコーディング ツリーをテストしています。DrScheme で次のコードを実行すると、期待どおりの結果が得られます。

(a d a b b c a)

ただし、(load "2.67.scm") を呼び出すか、mzscheme -f 2.67.scm を実行して、mzscheme でこの同じコードを実行すると、次のように報告されます。

symbols: expected symbols as arguments, given: (leaf D 1)

私の質問は：なぜですか？mzscheme と drscheme がプログラム定義をロードするための異なる規則を使用しているからでしょうか? プログラムコードは以下です。

;; Define an encoding tree and a sample message
;; Use the decode procedure to decode the message, and give the result. 

(define (make-leaf symbol weight)
  (list 'leaf symbol weight))
(define (leaf? object)
  (eq? (car object) 'leaf))
(define (symbol-leaf x) (cadr x))
(define (weight-leaf x) (caddr x))

(define (make-code-tree left right)
  (list left
        right
        (append (symbols left) (symbols right))
        (+ (weight left) (weight right))))

(define (left-branch tree) (car tree))
(define (right-branch tree) (cadr tree))

(define (symbols tree)
  (if (leaf? tree)
      (list (symbol-leaf tree))
      (caddr tree)))
(define (weight tree)
  (if (leaf? tree)
      (weight-leaf tree)
      (cadddr tree)))

(define (decode bits tree)
  (define (decode-1 bits current-branch)
    (if (null? bits)
        '()
        (let ((next-branch
               (choose-branch (car bits) current-branch)))
          (if (leaf? next-branch)
              (cons (symbol-leaf next-branch)
                    (decode-1 (cdr bits) tree))
              (decode-1 (cdr bits) next-branch)))))
  (decode-1 bits tree))
(define (choose-branch bit branch)
  (cond ((= bit 0) (left-branch branch))
        ((= bit 1) (right-branch branch))
        (else (error "bad bit -- CHOOSE-BRANCH" bit))))

(define (test s-exp)
  (display s-exp)
  (newline))

(define sample-tree
  (make-code-tree (make-leaf 'A 4)
                  (make-code-tree
                   (make-leaf 'B 2)
                   (make-code-tree (make-leaf 'D 1)
                                   (make-leaf 'C 1)))))

(define sample-message '(0 1 1 0 0 1 0 1 0 1 1 1 0))

(test (decode sample-message sample-tree))
4

1 に答える 1

6

デフォルトでは、MzScheme は の既存の定義があるモードで開始し、symbols認識している関数をインライン化します。つまり、make-code-tree定義をコンパイルするときに、認識しているバインディングを使用します。後で をコンパイルするときsymbols、以前の定義には影響しません。

これに対処する最も簡単な方法は、コードの前に . を付けて、コードをモジュールにすること#lang schemeです。

于 2008-12-25T06:36:43.667 に答える