0 
module Main where

data Toy b next =
    Output b next
  | Bell next
  | Done

data FixE f e = Fix (f (FixE f e)) | Throw e

-- The working monadic function
catch :: (Functor f) => FixE f e1 -> (e1 -> FixE f e2) -> FixE f e2
catch (Fix x) f = Fix (fmap (`catch` f) x)
catch (Throw e) f = f e

-- Type error
applicate_fixe :: (Functor f) => FixE f (e1 -> e2) -> FixE f e1 -> FixE f e2
applicate_fixe a b = a `catch` (`fmap` b)

-- Type error
applicate_fixe' :: (Functor f) => FixE f (e1 -> e2) -> FixE f e1 -> FixE f e2
applicate_fixe' (Throw f) b = fmap f b
applicate_fixe' (Fix f) b = Fix (fmap (`applicate_fixe` b) f)

main :: IO()
main = print "Hello."

C:\!Various_Exercises\Haskell_Exercises\Free_Monad_Stuff\test.hs: 15, 33
Could not deduce (Functor (FixE f)) arising from a use of `fmap'
from the context (Functor f)
  bound by the type signature for
             applicate_fixe :: Functor f =>
                               FixE f (e1 -> e2) -> FixE f e1 -> FixE f e2
  at test.hs:14:19-76
In the second argument of `catch', namely `(`fmap` b)'
In the expression: a `catch` (`fmap` b)
In an equation for `applicate_fixe':
    applicate_fixe a b = a `catch` (`fmap` b)
C:\!Various_Exercises\Haskell_Exercises\Free_Monad_Stuff\test.hs: 18, 31
Could not deduce (Functor (FixE f)) arising from a use of `fmap'
from the context (Functor f)
  bound by the type signature for
             applicate_fixe' :: Functor f =>
                                FixE f (e1 -> e2) -> FixE f e1 -> FixE f e2
  at test.hs:17:20-77
In the expression: fmap f b
In an equation for applicate_fixe':
    applicate_fixe' (Throw f) b = fmap f b

Free Monad を理解するためにこのチュートリアルを終了し、演習として Applicative 関数も実行しようとしています。正直なところ、これらのエラーが何を意味するのかわかりません。

data FixE f e = Fix (f (FixE f e)) | Throw eまた、 の型シグネチャが正確にどうあるべきかわかりません。f (FixE f e)最初はタプルのはずだと思っていましたが、1つの引数のように見えるため、(FixE f e)実際には最初の の型引数fです。しかし、そうであれば、f内部にFixE f eも型引数が必要ではないでしょうか?

編集：

applicate_fixe :: (Functor f) => FixE f (e1 -> e2) -> FixE f e1 -> FixE f e2
applicate_fixe (Fix f) b = Fix (fmap (`applicate_fixe` b) f) -- Works as the f argument in fmap is a functor
applicate_fixe (Throw f) (Fix b) = fmap f b -- The b is of type f (FixE f e1) so it is clearly a functor and yet the type system rejects it.

何よりも、この最後の部分がわかりません。また、ファンクターのインスタンスを正確に定義する必要があるのは何ですか? fは、上記の定義ですでにその制約を持っている必要があります。

Edit2: おそらく、FixE には Functor インスタンスが必要だということです。

instance Functor f => Functor (FixE f) where
  fmap f (Fix x) = fmap f x -- Type error
  fmap f (Throw e) = Throw (f e)

これが私のベストショットですが、最初の行で型 f が硬すぎると不平を言っています。

4

1 に答える 1

1 
module Main where

data Toy b next =
    Output b next
  | Bell next
  | Done

instance Functor f => Functor (FixE f) where
  fmap f (Fix x) = Fix (fmap (fmap f) x)
  fmap f (Throw e) = Throw (f e)

data FixE f e = Fix (f (FixE f e)) | Throw e

-- Monadic function
catch :: (Functor f) => FixE f e1 -> (e1 -> FixE f e2) -> FixE f e2
catch (Fix x) f = Fix (fmap (`catch` f) x)
catch (Throw e) f = f e

-- Applicative function
applicativeFixE :: (Functor f) => FixE f (e1 -> e2) -> FixE f e1 -> FixE f e2
applicativeFixE (Fix f) b = Fix (fmap (`applicativeFixE` b) f)
applicativeFixE (Throw f) b = fmap f b

main :: IO()
main = print "Hello."

コメントに基づいて、アプリカティブ機能を実装することができました。上記の方法が、私が試したいくつかの代替手段と比較してまだ機能する理由は完全にはわかりませんが、型チェックを行います。

みんな、ありがとう。

于 2016-10-01T06:56:30.057 に答える