1

TPanelnamedから派生したカスタム コントロールがありTTestCtrlます。TImage32(Graphics32 から) を保持します。

ユーザーが画像をダブルクリックすると、メッセージが表示されます。問題は、メッセージを閉じた後、フォーカスがメイン アプリケーションに戻らないことです。そのため、メインアプリ/メインフォームで何をクリックしても、最初のクリックは失われます。

奇妙なこと:メインフォームからMesaj()ではなく、メインフォームからプロシージャを呼び出すと、TTestCtrl機能します(最初のクリックはもう失われません):

unit DerivedControl;

interface

uses
  System.SysUtils, System.Classes, Vcl.Controls, Vcl.ExtCtrls, Vcl.Dialogs, Vcl.Forms, GR32, GR32_Image;

type
  TTestCtrl = class(TPanel)
  private
    Img: TImage32;
  protected
    procedure ChromaDblClick(Sender: TObject);
  public
    constructor Create(AOwner: TComponent); override;
  published
  end;

procedure Mesaj(const MessageText, Title: string);

implementation

procedure Mesaj(const MessageText, Title: string);
begin
{$IFDEF MSWINDOWS}
   Application.MessageBox(PChar(MessageText), PChar(Title), 0)  { 'Title' will appear in window's caption }
{$ELSE}
   MessageDlg(MessageText, mtInformation, [mbOk], 0);
{$ENDIF}
end;

constructor TTestCtrl.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  Width         := 200;
  Height        := 86;
  Img := TImage32.Create(Self);
  Img.Parent        := Self;
  Img.Align         := alClient;
  Img.OnDblClick    := ChromaDblClick;
end;

procedure TTestCtrl.ChromaDblClick(Sender: TObject);
begin
  Mesaj('Caption', 'From derived control');      // focus lost
end;

end.

以下の単純/最小限のアプリケーションはテスターです。

unit TesterForm;

interface

uses
  System.SysUtils, System.Classes, Vcl.StdCtrls, Vcl.Samples.Spin, Vcl.Controls, vcl.Forms, DerivedControl;

type
  TfrmTester = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
  public
  end;

var
  frmTester: TfrmTester;

implementation

{$R *.dfm}

var
  Ctrl: TTestCtrl;

procedure TfrmTester.FormCreate(Sender: TObject);
begin
  Ctrl := TTestCtrl.Create(Self);
  Ctrl.Parent := Self;
end;

procedure TfrmTester.Button1Click(Sender: TObject);
begin
  Mesaj('Caption', 'From main form');      // works
end;

end.
4

1 に答える 1

1

これを試して ：

procedure TTestCtrl.ChromaDblClick(Sender: TObject);
var F : TcustomForm;
begin
  Mesaj('Caption', 'From derived control');      // focus lost
  F := GetParentForm(Self);
  if Assigned(F) then F.BringToFront;

end;
于 2016-10-22T18:21:58.030 に答える