3

jack コンパイラで Android Annotations を使用する方法を知っている人はいますか?

ここに私の app/build.gradle とここに私のプロジェクト build.gradle

この構成では、プロジェクトをビルドするときに次のエラー メッセージが表示されます。

Error:Could not get unknown property 'classpath' for task ':app:transformJackWithJackForDebug' of type com.android.build.gradle.internal.pipeline.TransformTask.
4

1 に答える 1

6

Jack アノテーション処理では機能しないため、android-aptプラグインとブロックを完全に削除する必要があります。aptまた、annotationProcessor構成でプロセッサを宣言する必要があります。最後に、注釈処理パラメーターを jack に追加する必要があります (バリアントごとの公開 API はまだありません)。

変更したbuild.gradleは次のとおりです。

repositories {
    jcenter()
    mavenCentral()
}


apply plugin: 'com.android.application'

android {
    compileSdkVersion 24
    buildToolsVersion "24.0.2"
    defaultConfig {
        applicationId "com.frlgrd.streamzone"
        minSdkVersion 21
        targetSdkVersion 24
        versionCode 1
        versionName "1.0"
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
        jackOptions {
            enabled true
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
}

// Android Annotations
def AAVersion = '4.0.0'

dependencies {

    // Google
    androidTestCompile('com.android.support.test.espresso:espresso-core:2.2.2', {
        exclude group: 'com.android.support', module: 'support-annotations'
    })
    compile 'com.android.support:appcompat-v7:24.2.1'
    compile 'com.android.support:design:24.2.1'

    // Android Annotations
    annotationProcessor "org.androidannotations:androidannotations:$AAVersion"
    compile "org.androidannotations:androidannotations-api:$AAVersion"

    // RX
    compile 'com.tbruyelle.rxpermissions:rxpermissions:0.7.1@aar'
    compile 'io.reactivex:rxandroid:1.2.1'
    compile 'io.reactivex:rxjava:1.1.6'
}

// add annotation processing options to jack
android.applicationVariants.all { variant ->
    variant.variantData.variantConfiguration.javaCompileOptions.annotationProcessorOptions
            .arguments = ['androidManifestFile': variant.outputs[0]?.processResources?.manifestFile?.absolutePath]
}
于 2016-10-23T10:16:14.303 に答える