1

Ocaml に Cohttp と Lwt を使用した単純な HTTP サーバーがあります。アプリケーションを実行すると、終了wrkするとすぐに約 50% の確率でクラッシュします。wrkクラッシュは、予期しない接続の切断によって引き起こされると思います。

コンソールに次のエラーが表示されます。

Fatal error: exception Unix.Unix_error(Unix.ECONNRESET, "read", "")
Raised by primitive operation at file "src/unix/lwt_bytes.ml", line 130, characters 42-84
Called from file "src/unix/lwt_unix.ml", line 489, characters 13-24

これを防ぐ方法はありますか？

私の完全なソースコードは次のとおりです。

(* server_test.ml *)
open Unix
open Lwt
open Cohttp
open Cohttp_lwt_unix
open Yojson
open Yojson.Basic.Util
open Core.Std

type create = {
username: string;
email: string;
password: string;
} [@@deriving yojson]

let insert coll doc =
    let _id = Core.Std.Uuid.to_string (Uuid.create ()) in
    let uri = Uri.make ~scheme:"http" ~host:"127.0.0.1" ~port:5984 ~path:(coll ^ "/" ^ _id) () in
    Cohttp_lwt_unix.Client.put ~body:(Cohttp_lwt_body.of_string (Yojson.Safe.to_string doc)) uri
    >|= fun (r, _) -> Code.code_of_status @@ Response.status r

let callback _conn req body =
    body |> Cohttp_lwt_body.to_string 
    >>= (fun body -> 
        let mc = Yojson.Safe.from_string body |> create_of_yojson in
        match mc with
        | Ok c -> 
            insert "users" (create_to_yojson c)
            >>= fun status -> print_endline @@ string_of_int status; 
                Server.respond_string ~status:(`Code status) ~body:(string_of_int status) ()
        | _ -> Server.respond_string ~status:`OK ~body: "Not OK" ())

let timeit _conn req body =
    let start = Unix.gettimeofday () in
    callback _conn req body 
    >>= 
    fun result ->
        let finish = Unix.gettimeofday () in
        Lwt_io.printlf "Execution time took %fms" ((finish -. start) *. 1000.0)
        >|= fun _ -> result

let server =
    Server.create ~mode:(`TCP (`Port 8000)) (Server.make timeit ())

let () = ignore (Lwt_main.run server)

ありがとう！

4

1 に答える 1

5

表示されているエラーは、クライアントが予期せず切断されたときに発生した未処理の例外によるものです。関連する例外は、Lwt の非同期例外フック ( http://ocsigen.org/lwt/2.6.0/api/Lwt#VALasync_exception_hook ) に渡されます。Lwt のデフォルトでは、バックトレースを出力し、終了コード でプログラムを終了します2。

これについては、cohttp github issue tracker で進行中の議論があります: https://github.com/mirage/ocaml-cohttp/issues/511

つまり、Lwt の非同期/「バックグラウンド」スレッドのカスタム例外ハンドラーを定義すると、クライアント エラーをキャプチャして無視/ログ/処理することができます。cohttp サーバーを起動する前に、次のようなものを追加します。

Lwt.async_exception_hook := (function
  | Unix.Unix_error (error, func, arg) ->
    Logs.warn (fun m ->
      m  "Client connection error %s: %s(%S)"
        (Unix.error_message error) func arg
    )
  | exn -> Logs.err (fun m -> m "Unhandled exception: %a" Fmt.exn exn)
);

https://github.com/mirage/ocaml-cohttp/issues/511#issuecomment-258510531から取得し、logsライブラリを使用してイベントをログに記録します: http://erratique.ch/software/logs

于 2016-11-08T22:24:48.380 に答える