2

Delphi（2006）からMySqlにアクセスするためにdevart（corelab）によるMydacコンポーネントを利用します。TClientDataSetのデータを操作する必要があることがよくあります。TMyQueryのデータセットをTClientDataSetに変換する最良の方法は何ですか。現在使用しています。

var
    MyQuery : TMyQuery;
    Dsp     : TDataSetProvider;
    Cds     : TClientDataSet;
begin
    MyQuery := nil;
    Dsp     := nil;
    Cds     := nil;
    try
        MyQuery            := TMyQuery.Create(nil);
        Dsp                := TDataSetProvider.Create(nil);
        Cds                := TClientDataSet.Create(nil);
        MyQuery.Connection := TheConnection;
        MyQuery.SQL.Text   := CmdStr;
        Dsp.DataSet := MyQuery;
        Cds.SetProvider(Dsp);
        Cds.Open;
        ////////////////////////////////////////////////////////////////////////
        ///                  MAKE USES OF THE CDS                             //
        ////////////////////////////////////////////////////////////////////////
    finally
        FreeAndNil(Cds);
        FreeAndNil(Dsp);
        FreeAndNil(MyQuery);
    end;
end;

これを行うためのより良い方法はありますか？

4

1 に答える 1

7

これが本当に頻繁に必要な場合は、次のように関数にします。

function CreateAndOpenClientDataset(AOwner: TComponent;
  AConnection: TConnection; ACommand: string): TClientDataSet;
var
  MyQuery: TMyQuery;
  Dsp: TDataSetProvider;
begin
  Result := TClientDataSet.Create(AOwner);
  try
    MyQuery := TMyQuery.Create(Result);
    MyQuery.Connection := AConnection;
    MyQuery.SQL.Text := ACommand;

    Dsp := TDataSetProvider.Create(Result);
    Dsp.DataSet := MyQuery;

    Result.SetProvider(Dsp);
    Result.Open;
  except
    Result.Free;
    raise;
  end;
end;

この関数は、TClientDataSet.Create（）の代わりにすべての場所で使用でき、例外が発生しない限り、所有するオープンTClientDataSetが与えられ、その方法で2つのヘルパーオブジェクトも解放されます。

（注：私はMS Sql ServerのDevArtコンポーネントのみを使用しているため、テストできません。コードにエラーが含まれている可能性がありますが、一般的な考え方は機能します。）

于 2009-01-01T16:29:13.717 に答える