5

2つのページフィールド値の値を読み取ってINIファイルに保存するにはどうすればよいですか？ISToolを使用してINIセクションで2つのキーペアを作成しました。これをリンクするにはどうすればよいですか？

INIセクションは次のようになります。

[INI]
Filename: {app}\prefs.ini; Section: AUTH; Key: USERNAME; String: 
Filename: {app}\prefs.ini; Section: AUTH; Key: PASSWORD; String:

ページは次のように作成されます。

AuthPage := CreateInputQueryPage(wpWelcome,
  'Account Information', 'Please enter your Account Information',
  '');
AuthPage.Add('Username:', False);
AuthPage.Add('Password:', True);

編集：

以下の追加を行いました。何らかの理由で機能しません：

SetIniString('AUTH', 'USERNAME', AuthPage.Values[0], '{app}\prefs.ini')
SetIniString('AUTH', 'PASSWORD', AuthPage.Values[1], '{app}\prefs.ini')
4

3 に答える 3

10

これは機能するはずです：

; Script generated by the Inno Setup Script Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

[Setup]
; NOTE: The value of AppId uniquely identifies this application.
; Do not use the same AppId value in installers for other applications.
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
AppId={{82C8C949-44A8-49C4-8CED-8DD0ACD0DCCF}
AppName=My Program
AppVerName=My Program 1.5
AppPublisher=My Company, Inc.
AppPublisherURL=http://www.example.com/
AppSupportURL=http://www.example.com/
AppUpdatesURL=http://www.example.com/
DefaultDirName={pf}\My Program
DefaultGroupName=My Program
OutputBaseFilename=setup
Compression=lzma
SolidCompression=yes

[Languages]
Name: "english"; MessagesFile: "compiler:Default.isl"

[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked

[Files]
Source: "C:\util\innosetup\5.3.7\Examples\MyProg.exe"; DestDir: "{app}"; Flags: ignoreversion

; NOTE: Don't use "Flags: ignoreversion" on any shared system files

[Icons]
Name: "{group}\My Program"; Filename: "{app}\MyProg.exe"
Name: "{commondesktop}\My Program"; Filename: "{app}\MyProg.exe"; Tasks: desktopicon

[Run]
Filename: "{app}\MyProg.exe"; Description: "{cm:LaunchProgram,My Program}"; Flags: nowait postinstall skipifsilent

[INI]
Filename: {app}\prefs.ini; Section: AUTH; Key: USERNAME; String: {code:GetUserName}
Filename: {app}\prefs.ini; Section: AUTH; Key: PASSWORD; String: {code:GetPassword}


[code]
var
AuthPage : TInputQueryWizardPage;

procedure InitializeWizard;
begin
AuthPage := CreateInputQueryPage(wpWelcome,
    'Account Information', 'Please enter your Account Information',
    '');
  AuthPage.Add('Username:', False);
  AuthPage.Add('Password:', True);
end;

function AuthForm_NextButtonClick(Page: TWizardPage): Boolean;
begin
  Result := True;
end;

function GetUserName(Param: String): string;
begin
result := AuthPage.Values[0];
end;

function GetPassword(Param: String): string;
begin
result := AuthPage.Values[1];
end;
于 2010-10-30T14:36:35.020 に答える
1

セクションエントリからスクリプト化された定数を使用します。[INI]

[INI]
Filename: {app}\prefs.ini; Section: AUTH; Key: USERNAME; String: {code:GetAuth|0}
Filename: {app}\prefs.ini; Section: AUTH; Key: PASSWORD; String: {code:GetAuth|1}

[Code]

var
  AuthPage: TInputQueryWizardPage;

procedure InitializeWizard();
begin
  AuthPage := CreateInputQueryPage(wpWelcome,
    'Account Information', 'Please enter your Account Information',
    '');
  AuthPage.Add('Username:', False);
  AuthPage.Add('Password:', True);
end;

function GetAuth(Param: String): string;
begin
  Result := AuthPage.Values[StrToInt(Param)];
end;

ユーザーが入力した値をINIファイルエントリに変換するロジックが複雑な場合は、SetIniStringfrom[Code]セクションを使用することをお勧めします。通常、CurStepChangedイベント関数から：

procedure CurStepChanged(CurStep: TSetupStep);
var
  IniFileName: string;
begin
  if CurStep = ssPostInstall then
  begin
    IniFileName := ExpandConstant('{app}\prefs.ini');
    SetIniString('AUTH', 'USERNAME', AuthPage.Values[0], IniFileName);
    SetIniString('AUTH', 'PASSWORD', AuthPage.Values[1], IniFileName);
  end;
end;
于 2017-05-19T05:42:54.437 に答える
0

定数ExpandConstant('{app}\prefs.ini')を拡張するために書く必要があると思います。{app}

于 2010-10-29T20:37:27.360 に答える