perl - Perlでの再帰関数のカプセル化

Question

私はここでうまく機能するコードを持っています：

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;



        my %graph =(
            F => ['B','C','E'],
            A => ['B','C'],
            D => ['B'],
            C => ['A','E','F'],
            E => ['C','F'],
            B => ['A','E','F']
        );

        sub findPaths {
            my( $seen,  $start, $end ) = @_;

            return [[$end]] if $start eq $end;

            $seen->{ $start } = 1;
            my @paths;
            for my $node ( @{ $graph{ $start } } ) {
                my %seen = %{$seen};
                next if exists $seen{ $node };
                push @paths, [ $start, @$_ ] for @{ findPaths( \%seen, $node, $end ) };
            }
            return \@paths;
        }


            my $start = "B";
            my $end   = "E";
        print "@$_\n" for @{ findPaths( {}, $start, $end ) };

私がやりたいのは、より一般的なサブルーチンを生成して\%graph, $start,$end、入力として受け取り、最終的な配列を返すようにすることです。

私はこの方法でそれをやろうとしましたが、コンパイルされません。

sub findPathsAll {

    my ($graph,$start,$end) = @_;

    my $findPaths_sub;
        $findPaths_sub {
            my( $seen) = @_;

            return [[$end]] if $start eq $end;

            $seen->{ $start } = 1;
            my @paths;
            for my $node ( @{ $graph{ $start } } ) {
                my %seen = %{$seen};
                next if exists $seen{ $node };
                push @paths, [ $start, @$_ ] for @{ &$findPaths_sub( \%seen, $node, $end ) };
            }
            return \@paths;
        }


    my @all;
    push @all,@$_ for @{ &$findPaths_sub( {}, $start, $end ) };
    return @all;
}

それを行う正しい方法は何ですか？

Answer 1

あなたが何findPathsAllを返したいのかわからないので、これはあなたが望むものではないかもしれません。とにかく、findPathsこれが字句再帰coderefへの翻訳です：

use Scalar::Util 'weaken';

sub findPathsAll {
  my ($graph,$start,$end) = @_;

  my $findPaths_sub;
  my $strongRef = $findPaths_sub = sub {
    my( $seen, $start, $end ) = @_;

    return [[$end]] if $start eq $end;

    $seen->{ $start } = 1;
    my @paths;
    for my $node ( @{ $graph->{ $start } } ) {
      my %seen = %{$seen};
      next if exists $seen{ $node };
      push @paths, [ $start, @$_ ]
          for @{ $findPaths_sub->( \%seen, $node, $end ) };
    }
    return \@paths;
  };

  weaken($findPaths_sub);       # Prevent memory leak

  my @all;
  push @all,@$_ for @{ $findPaths_sub->( {}, $start, $end ) };
  return @all;

  ## The above turns all the paths into one big list of nodes.
  ## I think maybe you meant this:
  #    return @{ $findPaths_sub->( {}, $start, $end ) };
  ## which would return a list of arrayrefs, one for each path.
}

いくつかのメモ：

次のようにcoderefを宣言します。

$var = sub { ... };

代入演算子と末尾のセミコロンに注意してください。coderefを再帰的にしたい場合は、すでに宣言している必要があります$var。（と言うmy $var = sub { ... };と、新しい変数はサブが作成されるまで存在しないため、参照できません$var。）

あなたはそれをこのように呼びます：

$var->(arg1, arg2, ...);

（機能する構文は他にもありますが、これが推奨される構文だと思います。）

私が投稿した最初のバージョンでは、微妙なメモリリークがありました。Perlは参照カウントガベージコレクターを使用します。つまり、自己参照データ構造を削除することはできません。のcoderefは$findPaths_subそれ自体への参照をキャプチャしたため、（プログラムが終了するまで）クリーンアップされることはありません。これを回避するために、Scalar :: Utilの関数（weaken彼のブログエントリでsingingfishで言及されている）を使用しています。 $strongRef使用が完了する前に、coderefがガベージコレクションされないようにするためにのみ使用されます。

Answer 2

先日、この問題についてブログを書きました。