2

以下は、アイテムの配列を受け入れ、各レコードvarchar2のレコードの内部 pk を返すために作成している関数です。type の配列をカーソル内の単純な sql クエリにNUMBER渡し、 type の変数を返す構文を取得するのに苦労しています。エラーは8,42行目、つまり関数に渡されたものです。私はplsqlを学んでいるので、このエラーについて教えてください。VARCHAR_ARRAYNUMBER_ARRAYFROM table_name WHERE column_name IN VARCHAR_ARRAY

  create or replace TYPE VARCHAR_ARRAY AS VARRAY(1000000) OF VARCHAR2(1000);
   /

  create or replace TYPE NUMBER_ARRAY AS VARRAY(1000000) OF NUMBER;
   /

  create or replace Function GET_PRODUCT_ID_ARR(V_PRODUCT_NUM_ARR IN VARCHAR_ARRAY)
  RETURN NUMBER_ARRAY 
  IS
     product_id_list number_array := number_array(); 
     CURSOR c1
     IS 
     SELECT cat_map_id 
     FROM mn_cat_map WHERE product_num IN (V_PRODUCT_NUM_ARR) and catalog_type = 'INT';
  v_output NUMBER;   
  BEGIN
      OPEN c1; 
      LOOP
          fetch c1 into product_id_list;
          EXIT WHEN c1%notfound;
          product_id_list.extend;
          product_id_list(product_id_list.count)  := v_output;
         dbms_output.put_line('Product ('||v_output ||'):'||product_id_list(v_output));
      END LOOP;
  Close c1;
  RETURN product_id_list;
  END;
  /
4

2 に答える 2

1

@ウィリアムが言っていることは、静かに真実です。VARRAY(1000000)推奨されません。のタイプをインプレースで作成できますtable。ただし、あなたが行ったことに従うと、コードにいくつかの間違いがあるようです。どのようにすればよいか、以下を参照してください。

テーブルの準備:

create table mn_cat_map(cat_map_id number,
                        product_num varchar2(1000),
                        catalog_type varchar2(10));
/
INSERT INTO T541682.MN_CAT_MAP (CAT_MAP_ID, PRODUCT_NUM, CATALOG_TYPE)
     VALUES (10, 'A123', 'INT');

INSERT INTO T541682.MN_CAT_MAP (CAT_MAP_ID, PRODUCT_NUM, CATALOG_TYPE)
     VALUES (2, 'B121', '2Wheer');

INSERT INTO T541682.MN_CAT_MAP (CAT_MAP_ID, PRODUCT_NUM, CATALOG_TYPE)
     VALUES (3, 'C645', '4Wheer');

COMMIT;

create or replace TYPE VARCHAR_ARRAY AS VARRAY(1000000) OF VARCHAR2(1000);
/
create or replace TYPE NUMBER_ARRAY AS VARRAY(1000000) OF NUMBER;
/

コード: 説明コメントをインラインで読む

CREATE OR REPLACE FUNCTION GET_PRODUCT_ID_ARR (V_PRODUCT_NUM_ARR  VARCHAR_ARRAY)
   RETURN NUMBER_ARRAY
IS
   product_id_list   number_array := number_array ();

   CURSOR c1(tbl_list VARCHAR_ARRAY)
   IS
      SELECT cat_map_id
        FROM mn_cat_map
       WHERE product_num  in (select column_value from table(tbl_list)) ---Checking if the item exists in the table with passed collection 
       AND catalog_type = 'INT';

   v_output     NUMBER:= 0;
BEGIN

    --not opening cursor and am not looking for processing any records.
   --OPEN c1(V_PRODUCT_NUM_ARR);

   --passing the input varray to the cursor.
   for i in c1(V_PRODUCT_NUM_ARR)
   loop

    v_output:=v_output + 1;

    product_id_list.extend;

    product_id_list(product_id_list.COUNT):= i.cat_map_id;

     DBMS_OUTPUT.put_line('Product (' || v_output || '):' ||product_id_list(product_id_list.COUNT));


   end loop;

   RETURN product_id_list;
END;
/

実行：

SQL> select GET_PRODUCT_ID_ARR(VARCHAR_ARRAY('A123','B121','C645')) COl1 from dual;

COL1
--------------------------------------------------------------------------------
NUMBER_ARRAY(10)

Product (1):10
于 2016-12-08T14:08:53.023 に答える
1

2 つの問題があります。

  1. テーブルにキャストvarrayする必要があります：

    CURSOR c1
IS 
SELECT cat_map_id 
FROM mn_cat_map 
WHERE product_num IN (select column_value from table(V_PRODUCT_NUM_ARR))
  and catalog_type = 'INT';

  2. bulk collect後に追加fetch:

    LOOP
  fetch c1 bulk collect into product_id_list limit 100;
  EXIT WHEN c1%notfound;
  product_id_list.extend;
  product_id_list(product_id_list.count)  := v_output;
  dbms_output.put_line('Product ('||v_output ||'):'||product_id_list(v_output));
  END LOOP;

と書くlimit 100と、ループごとに 100 個のレコードが に挿入されproduct_id_listます。句を省略できlimitます。この場合、1 回のフェッチですべてのレコードを取得します。

EDIT
結果の表示方法:

declare 
  myarray varchar_array; 
  my_num_array number_array;
begin 
  myarray := varchar_array(); 
  myarray.extend(2);
  myarray(1) := '151043'; 
  myarray(2) := '2895'; 
  my_num_array := GET_PRODUCT_ID_ARR(myarray);
  for i in 1 .. my_num_array.count loop
    dbms_output.put_line(my_num_array(i)); 
  end loop; 
end;
/
于 2016-12-08T07:44:49.333 に答える