1

動的テキスト フィールドを持つ親スプライトにマスクを追加すると、テキストのアンチエイリアシングが失われます。親にマスクを適用し、その後それ自体にマスクを適用しながら、テキストのアンチエイリアスを維持するにはどうすればよいですか。

フォントが埋め込まれ、テキスト フィールドがアニメーション化されるため、親と共にマスクする必要があります。

代替テキスト

package
{   
import flash.display.Sprite;
import flash.display.Shape;
import flash.text.*;

public class Test extends Sprite
    {
    public function Test()
        {
        //Create Background Canvas
        var canvas:Sprite = new Sprite();
        canvas.graphics.beginFill(0xFF0000)
        canvas.graphics.drawRect(0, 0, 100, 100);

        //Create Dynamic Text
        var field:TextField = new TextField();
        field.width = 100;
        field.autoSize = TextFieldAutoSize.LEFT;
        field.selectable = false;
        field.text = "Dynamic\nText";

        var format:TextFormat = new TextFormat();
        format.font = "Myriad Pro";
        format.color = 0xFFFFFF;
        format.size = 14;
        field.setTextFormat(format);

        //Add Dynamic Text To Background Canvas
        field.x = canvas.width /2  - field.width / 2;
        field.y = canvas.height / 2 - field.height / 2;
        canvas.addChild(field);

        //Create Mask
        var canvasMask:Shape = new Shape();
        canvasMask.graphics.beginFill(0);
        canvasMask.graphics.drawRoundRect(0, 0, 100, 100, 50);

        //Add Background Canvas And Mask To Display List
//      canvas.mask = canvasMask;
//      addChild(canvasMask);
        addChild(canvas);
        }
    }
}
4

1 に答える 1

1

これは、マスクを適用するときに TextField がビットマップとしてキャッシュされる方法に関係しているようです。実際、TextField の cacheAsBitmap プロパティを切り替えるだけで、同じ動作を再現できました。

これらの行を追加すると、問題が解決するようです。

    field.embedFonts = true;
    field.antiAliasType = AntiAliasType.ADVANCED;
    //you can adjust the thickness & sharpness if needed
    field.thickness = 200;
于 2010-11-08T02:11:40.753 に答える