automator - Automator で指定されたファイル名で名前が付けられた新しいフォルダーを作成します。

Question

入力に使用されるファイルのファイル名で名前が付けられた新しいフォルダーを作成したいと思います。

例：

ファイル「test (test.jpg)」で新しいサービスを使用する場合、「test (test)」という名前のフォルダーを自動的に作成したいと考えています。

Answer 1

通常の Automator アクションでこれを行うには、元の入力を保存し、名前を取得し、フォルダーを作成し、元の入力を元に戻す必要があるため、少し複雑になります。AppleScript の実行アクションを使用して、そのほとんどを実行できます。元の入力と作成されたフォルダー パスで何をしたいかによって異なりますが、一度に。

次のRun AppleScriptアクションは、入力項目の名前で新しいフォルダーを作成し (サービスは複数の項目を渡すことができることに注意してください)、元の入力のみを渡します。新しいフォルダーは同じ親フォルダーに作成されます。エラー処理 (名前の重複など) は実行されません。

on run {input, parameters} -- make new folders from base file names

    set output to {}

    repeat with anItem in the input -- step through each item in the input

        set anItem to anItem as text
        tell application "System Events" to tell disk item anItem
            set theContainer to path of container
            set {theName, theExtension} to {name, name extension}
        end tell
        if theExtension is in {missing value, ""} then
            set theExtension to ""
        else
            set theExtension to "." & theExtension
        end if
        set theName to text 1 thru -((count theExtension) + 1) of theName -- the name part

        tell application "Finder"
            make new folder at folder theContainer with properties {name:theName}
            set end of output to result as alias
        end tell
    end repeat

    return input -- or output
end run