vim - タブをvimのスペースに置き換えます

Question

gVimでタブをスペースに変換したいと思います。次の行を追加しました_vimrc：

set tabstop=2

2つのスペースで停止するように機能しますが、それでも1つのタブキーが挿入されているように見えます（後でスペースをカウントするためにhキーを使用しようとしました）。

gVimでタブをスペースに変換するにはどうすればよいですか？

Answer 1

他の回答に従ってexpandtabをオンにしたら、新しい設定に従って既存のファイルを変換する非常に便利な方法は次のとおりです。

:retab

現在のバッファで動作します。

Answer 2

IIRC、次のようなもの：

set tabstop=2 shiftwidth=2 expandtab

トリックを行う必要があります。すでにタブがある場合は、それを素敵なグローバルREでフォローアップして、ダブルスペースに置き換えます。

置き換えたいタブがすでにある場合は、

:retab

Answer 3

試す

set expandtab

ソフトタブ用。

既存のタブを修正するには：

:%s/\t/  /g

タブストップをすでに2スペースに設定しているので、2スペースを使用しました。

Answer 4

これは私のために働いた：

最初にこれを行うとタブが表示されます：

:set list

次に、タブを置き換えることができるようにするには、次のようにします。

:set expandtab

それから

:retab

すべてのタブがスペースに置き換えられたので、次のように通常の表示に戻ることができます:

:set nolist

Answer 5

gg=Gファイル全体を再インデントし、同僚からファイルで取得したすべてではないにしてもほとんどのタブを削除します。

Answer 6

.vimrcに次の行を追加します

set expandtab
set tabstop=4
set shiftwidth=4
map <F2> :retab <CR> :wq! <CR>

vimでファイルを開き、F2を押します。タブは4つのスペースに変換され、ファイルは自動的に保存されます。

Answer 7

\tスペースを 8 つに等しくしたい場合は、次の設定を検討してください。

   set softtabstop=2 tabstop=8 shiftwidth=2

これにより、1 回押すごとに 2 つのスペースが与えられます<TAB>が、実際\tのコードでは 8 文字として表示されます。

Answer 8

この記事には、タブ + スペースを処理し、それらの間で変換するための優れた vimrc スクリプトがあります。

次のコマンドが提供されます。

Space2Tab インデントのみで、スペースをタブに変換します。

Tab2Space インデント内のみで、タブをスペースに変換します。

RetabIndent Space2Tab ('expandtab' が設定されている場合) または Tab2Space (そうでない場合) を実行します。

各コマンドは、タブ列のスペースの数を指定する引数を受け入れます。デフォルトでは、「tabstop」設定が使用されます。

ソース: http://vim.wikia.com/wiki/Super_retab#Script

" Return indent (all whitespace at start of a line), converted from
" tabs to spaces if what = 1, or from spaces to tabs otherwise.
" When converting to tabs, result has no redundant spaces.
function! Indenting(indent, what, cols)
  let spccol = repeat(' ', a:cols)
  let result = substitute(a:indent, spccol, '\t', 'g')
  let result = substitute(result, ' \+\ze\t', '', 'g')
  if a:what == 1
    let result = substitute(result, '\t', spccol, 'g')
  endif
  return result
endfunction

" Convert whitespace used for indenting (before first non-whitespace).
" what = 0 (convert spaces to tabs), or 1 (convert tabs to spaces).
" cols = string with number of columns per tab, or empty to use 'tabstop'.
" The cursor position is restored, but the cursor will be in a different
" column when the number of characters in the indent of the line is changed.
function! IndentConvert(line1, line2, what, cols)
  let savepos = getpos('.')
  let cols = empty(a:cols) ? &tabstop : a:cols
  execute a:line1 . ',' . a:line2 . 's/^\s\+/\=Indenting(submatch(0), a:what, cols)/e'
  call histdel('search', -1)
  call setpos('.', savepos)
endfunction

command! -nargs=? -range=% Space2Tab call IndentConvert(<line1>,<line2>,0,<q-args>)
command! -nargs=? -range=% Tab2Space call IndentConvert(<line1>,<line2>,1,<q-args>)
command! -nargs=? -range=% RetabIndent call IndentConvert(<line1>,<line2>,&et,<q-args>)

これは、最初に解決策を探しに行ったとき、ここでの回答よりも少し役に立ちました。

Answer 9

最初にファイル内のタブを検索します: /^I :set expandtab :retab

動作します。