2

gen_server の init 部分で実行時エラーが発生しました。- process_flag(trap_exit,true) で開始する初期化 - gen_server は監視ツリーの一部 終了モジュールで理由を表示しようとしましたが、別の場所で終了しているようです。- なぜ終了が呼び出されないのですか? アプリケーションは理由としてシャットダウンで停止します。- 実行時エラーをキャッチする方法と場所は?

4

1 に答える 1

4

terminateコールバックは通常、この状況で呼び出されます。つまり、出口をトラップしたためです。

これが当てはまらない唯一の場所は、init-function でクラッシュが発生した場合です。その場合、責任は監督者にあり、通常は結果として自己終了します。次に、このエラーは、アプリケーション全体が終了するまでスーパーバイザー ツリーをクロールします。

通常、スーパーバイザは、コンテキストが に設定されたスーパーバイザ レポートをログに記録しますstart_error。これは、管理ツリーの一部に対処すべき問題があることを示すヒントです。エラーが発生する場所について間違った仮定をしている可能性があるため、これを確認する必要があります。

ここから編集

あなたの問題は、SASL についてまったく知らないことです。それを勉強してください。使用方法の例を次に示します。

あなたの例から巻き上げられたコード:

まず、bahlonga は、Erlang に gen_server があることを伝える必要がありました。

-module(foo).
-behaviour(gen_server).
-export([start_link/0]).
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
     terminate/2, code_change/3]).

#state{} レコードをハックして、コードで使用できるようにします

-record(state, { name, port, socket_listen }).

基本的な start_linkage...

start_link() ->
    gen_server:start_link({local, foo}, ?MODULE, [], []).

あなたのinit関数、スポーンの問題が含まれています。

init([]) ->
    Port = 3252,
    Name = "foo",

上記では、簡単にするために少しハックしました...

    process_flag(trap_exit, true),
    erlang:error(blabla),
    Opts = [binary, {reuseaddr, true},
        {backlog,5}, {packet, 0}, {active, false}, {nodelay, true}],
    case gen_tcp:listen(Port,Opts) of
    {ok,Socket_Listen} ->
        logger:fmsg("--> [~s,init] Socket_Listen crée = ~p",
            [Name,Socket_Listen]),
        {ok,handle_accept(#state{socket_listen=Socket_Listen})};
    {error, Reason} ->
        logger:fmsg("--> [~s,init] Erreur, Raison =~p",
            [Name,Reason]), {stop, Reason}
    end.

不足している機能のハック....

handle_accept(_) ->
    #state{}.

残りは基本的なものです...ので、省略します。

foo_supのスーパーバイザーの場合foo:

-module(foo_sup).
-behaviour(supervisor).
-export([start_link/0]).
-export([init/1]).
-define(SERVER, ?MODULE).

基本的な開始リンク...

start_link() ->
    supervisor:start_link({local, ?SERVER}, ?MODULE, []).

基本チャイルドスペック。foo の子を起動して実行します...

init([]) ->
    FooCh = {foo, {foo, start_link, []},
         permanent, 2000, worker, [foo]},
    {ok, {{one_for_all,0,1}, [FooCh]}}.

SASL を有効にして Erlang を起動します。

 jlouis@illithid:~$ erl -boot start_sasl
 Erlang R14B02 (erts-5.8.3) [source] [64-bit] [smp:2:2] [rq:2] [async-threads:0] [hipe] [kernel-poll:false]

 =PROGRESS REPORT==== 9-Dec-2010::01:01:51 ===
 [..]
 Eshell V5.8.3  (abort with ^G)

スーパーバイザーを生成してみましょう...

 1> foo_sup:start_link().

そして、これを取得します：

=CRASH REPORT==== 9-Dec-2010::01:05:48 ===
  crasher:
    initial call: foo:init/1
    pid: <0.58.0>
    registered_name: []
    exception exit: {blabla,[{foo,init,1},
                             {gen_server,init_it,6},
                             {proc_lib,init_p_do_apply,3}]}

foo:init/1上で、例外が原因でクラッシュしたことがわかりますblabla。

      in function  gen_server:init_it/6
    ancestors: [foo_sup,<0.45.0>]
    messages: []
    links: [<0.57.0>]
    dictionary: []
    trap_exit: true
    status: running
    heap_size: 233
    stack_size: 24
    reductions: 108
  neighbours:

そして今、監督者は問題について報告することができます!

=SUPERVISOR REPORT==== 9-Dec-2010::01:05:48 ===
     Supervisor: {local,foo_sup}
     Context:    start_error

文脈はまさに私が言った通りです...

     Reason:     {blabla,[{foo,init,1},
                          {gen_server,init_it,6},
                          {proc_lib,init_p_do_apply,3}]}

そして予想通りの理由。

     Offender:   [{pid,undefined},
                  {name,foo},
                  {mfargs,{foo,start_link,[]}},
                  {restart_type,permanent},
                  {shutdown,2000},
                  {child_type,worker}]
于 2010-12-08T16:17:31.713 に答える