0

あるOutlookPSTから別のOutlookPSTにフォルダーとサブフォルダーの構造をコピーしようとしていますが、次のFolders.Add()ステートメントで問題が発生します。

Private Sub Process(S As MAPIFolder, T As MAPIFolder, RootLevel As Boolean, BeforeDate As Date)
Dim N As NameSpace, F As MAPIFolder, G As MAPIFolder

    ' S is source folder (parameter)
    ' T is target folder (parameter)
    ' F is current source subfolder for recursion (private)
    ' G is target folder for recursion (private)

    Set N = Application.GetNamespace("MAPI")

    ' recurse through subfolders
    For Each F In S.Folders
        If F.Items.Count <> 0 Or F.Folders.Count <> 0 Then          ' process only if items or subfolders found

            If FoundFolder(T, F) Then                               ' this function works fine
                Set G = T.Folders(F.Name)                           ' found - just assign
            Else
                Set G = T.Folders.Add(F.Name, N.GetDefaultFolder(F.DefaultItemType))        ' not found - create
            End If
            '
            ' more code (working well)
            '                
            ' process next level without Root flag
            Process F, G, False, BeforeDate
        End If
    Next F
    Set F = Nothing
    Set G = Nothing
End Sub

Folders.Add()ステートメントでパラメーターをまったく指定しない限り、TypeDefaultType olMailItemを持つフォルダーが作成されます（ルートフォルダーがメールフォルダーであるため）。ただし、ソースフォルダと同じ種類のフォルダを作成したいと思います。

最初の独特の観察：

  • VBAヘルプ、MSNなどは、Folders.Add（Name、Type）TypeはオプションのLongであると述べています。
  • VBAエディターによると（入力時のツールチップで）タイプはMAPIFolderです

2番目の観察：Type引数を設定しようとすると、エラーが発生します

エラー-2147024809（80070057）

操作を完了できませんでした。1つ以上のパラメーター値が無効です

私は以下を試しました

' Type as Long
Set G = T.Folders.Add(F.Name, 0)
Set G = T.Folders.Add(F.Name, olMailItem)
Set G = T.Folders.Add(F.Name, OlItemType.olMailItem)
Set G = T.Folders.Add(F.Name, F.DefaultItemType) ' this is what I actually want
' Type as MAPIFolder
Set G = T.Folders.Add(F.Name, F)
Set G = T.Folders.Add(F.Name, N.GetDefaultFolder(F.DefaultItemType))

エラー-エラー-エラー

ソースフォルダと同じタイプのフォルダを作成するにはどうすればよいですかF

誰か助けて....お願いします

よろしくMikeD

4

1 に答える 1

0

OK解決しました....問題は単に間違った列挙を使用したことでした:-(

Source以下のようなタイプのMAPIフォルダーを作成する関数は次のTargetようになります。

Private Function CreateFolderOfType(Source As MAPIFolder, Target As MAPIFolder) As MAPIFolder
Dim F As MAPIFolder

    Set CreateFolderOfType = Nothing
    ' if source already exists below Target
    For Each F In Target.Folders
        If F.Name = Source.Name Then
            Set CreateFolderOfType = F
            Exit Function
        End If
    Next F

    Select Case Source.DefaultItemType
    Case olAppointmentItem
        Set CreateFolderOfType = Target.Folders.Add(Source.Name, olFolderCalendar)
    Case olContactItem, olDistributionListItem
        Set CreateFolderOfType = Target.Folders.Add(Source.Name, olFolderContacts)
    Case olJournalItem
        Set CreateFolderOfType = Target.Folders.Add(Source.Name, olFolderJournal)
    Case olMailItem, olPostItem
        Set CreateFolderOfType = Target.Folders.Add(Source.Name, olFolderInbox)
    Case olNoteItem
        Set CreateFolderOfType = Target.Folders.Add(Source.Name, olFolderNotes)
    Case olTaskItem
        Set CreateFolderOfType = Target.Folders.Add(Source.Name, olFolderTasks)
    Case Else
        Set CreateFolderOfType = Target.Folders.Add(Source.Name)
    End Select
End Function
于 2011-03-21T19:20:39.607 に答える