0

これが私がやっていることです。カスタム拡張子（.cpm）で終わるドキュメント用のperlインタープリターを作成しています。私は周りを見回して見つけました

HTML::Parserがその方法のようです。私が求めているのは、特別なタグを持つドキュメントを解析するための簡単なチュートリアルです。たとえば、HTMLドキュメントを解析する方法を示すものが必要ですが、<putinbold>が検出されると、それが。に置き換えられ<b>ます。

私が欲しいものの例-

<html>
This is HTML talking
<liamslanguage>say "This is Liams language speaking"</liamslanguage>
</html>

4

1 に答える 1

8

構文解析の重要な部分は、権利に権利をHTML::Parser割り当てることです。サンプルプログラム：handlersargspec

#!/usr/bin/env perl

use strict;
use warnings;

use HTML::Parser;

my $html;
sub replace_tagname {
    my ( $tagname, $event ) = @_;

    if ( $tagname eq 'liamslanguage' ) {
        $tagname = 'b';
    }

    if ( $event eq 'start' ) {
        $html .= "<$tagname>";
    }
    elsif ( $event eq 'end' ) {
        $html .= "</$tagname>";
    }
}

my $p = HTML::Parser->new(
    'api_version' => 3,
    'start_h'     => [ \&replace_tagname,      'tagname, event' ],
    'default_h'   => [ sub { $html .= shift }, 'text'           ],
    'end_h'       => [ \&replace_tagname,      'tagname, event' ],
);
$p->parse( do { local $/; <DATA> } );
$p->eof();

print $html;

__DATA__
<html>
This is HTML talking
<liamslanguage>say "This is Liams language speaking"</liamslanguage>
</html>
于 2010-12-15T01:00:46.400 に答える