2

「ハッシュの配列」の要素を配列として関数に渡すにはどうすればよいですか?

たとえば、すべて$link->{text}を配列としてsort()関数に渡したいとします。

#!/usr/bin/perl
use strict; use warnings;

my $field = <<EOS;
<a href="baboon.html">Baboon</a>
<a href="antelope.html">Antelope</a>
<a href="dog.html">dog</a>
<a href="cat.html">cat</a>
EOS

#/ this comment is to unconfuse the SO syntax highlighter. 
my @array_of_links;
while ($field =~ m{<a.*?href="(.*?)".*?>(.*?)</a>}g) {
    push @array_of_links, { url => $1, text => $2 };
}
for my $link (@array_of_links) {
    print qq("$link->{text}" goes to -> "$link->{url}"\n);
}
4

2 に答える 2

6

リンクをテキストで並べ替えたい場合は、

my @sorted_links = sort { $a->{text} cmp $b->{text} } @array_of_links;

実際にテキストを取得して並べ替えたい場合は、

my @text = sort map $_->{text}, @array_of_links;
于 2010-12-15T23:29:51.557 に答える
3

注意を怠って、HTML パーサーを使用して HTML を解析することをお勧めします。

use strict; use warnings;

use HTML::TokeParser::Simple;

my $field = <<EOS;
<a href="baboon.html">Baboon</a>
<a href="antelope.html">Antelope</a>
<a href="dog.html">dog</a>
<a href="cat.html">cat</a>
EOS

my $parser = HTML::TokeParser::Simple->new(string => $field);

my @urls;

while ( my $tag = $parser->get_tag ) {
    next unless $tag->is_start_tag('a');
    next unless defined(my $url = $tag->get_attr('href'));
    my $text = $parser->get_text('/a');
    push @urls, { url => $url, text => $text };
}

@urls = sort {
    $a->{text} cmp $b->{text} ||
    $a->{url}  cmp $b->{url}
} @urls;

use YAML;
print Dump \@urls;
于 2010-12-16T00:51:37.100 に答える