5

編集：解決しました。ソースファイルで言語拡張を有効にしても、GHCiで言語拡張が有効にならないことに気づいていませんでした。解決策は:set FlexibleContextsGHCiでした。

私は最近、Haskellのクラスとインスタンスの型宣言がホーン節であることを発見しました。そこで、 The ArtofPrologの第3章の算術演算をHaskellにエンコードしました。例えば：

fac(0,s(0)).
fac(s(N),F) :- fac(N,X), mult(s(N),X,F).

class Fac x y | x -> y
instance Fac Z (S Z)
instance (Fac n x, Mult (S n) x f) => Fac (S n) f

pow(s(X),0,0) :- nat(X).
pow(0,s(X),s(0)) :- nat(X).
pow(s(N),X,Y) :- pow(N,X,Z), mult(Z,X,Y).

class Pow x y z | x y -> z
instance (N n) => Pow (S n) Z Z
instance (N n) => Pow Z (S n) (S Z)
instance (Pow n x z, Mult z x y) => Pow (S n) x y

Prologでは、値はプルーフの（論理）変数に対してインスタンス化されます。しかし、Haskellで型変数をインスタンス化する方法がわかりません。つまり、HaskellがPrologクエリに相当するものが何であるかがわかりません

?-f(X1,X2,...,Xn)

は。私は

:t undefined :: (f x1 x2 ... xn) => xi

Haskellがインスタンス化する原因になりますxiが、これを有効Non type-variable argument in the constraintにしてもエラーが発生します。FlexibleContexts

4

1 に答える 1

3

Prologサンプルについてはわかりませんが、Haskellで次のように定義します。

{-# LANGUAGE MultiParamTypeClasses, EmptyDataDecls, FlexibleInstances,
FlexibleContexts, UndecidableInstances, TypeFamilies, ScopedTypeVariables #-}

data Z
data S a
type One = S Z
type Two = S One
type Three = S Two
type Four = S Three 


class Plus x y r
instance (r ~ a) => Plus Z a r
instance (Plus a b p, r ~ S p) => Plus (S a) b r

p1 = undefined :: (Plus Two Three r) => r


class Mult x y r
instance (r ~ Z) => Mult Z a r
instance (Mult a b m, Plus m b r) => Mult (S a) b r

m1 = undefined :: (Mult Two Four r) => r


class Fac x r
instance (r ~ One) => Fac Z r
instance (Fac n r1, Mult (S n) r1 r) => Fac (S n) r

f1 = undefined :: (Fac Three r) => r


class Pow x y r
instance (r ~ One) => Pow x Z r
instance (r ~ Z) => Pow Z y r
instance (Pow x y z, Mult z x r) => Pow x (S y) r

pw1 = undefined :: (Pow Two Four r) => r

-- Handy output
class (Num n) => ToNum a n where
    toNum :: a -> n
instance (Num n) => ToNum Z n where
    toNum _ = 0
instance (ToNum a n) => ToNum (S a) n where
    toNum _ = 1 + toNum (undefined :: a) 

main = print $ (toNum p1, toNum m1, toNum f1, toNum pw1)

アップデート：

danportinが以下のコメントで指摘しているように、TypeFamiliesの「レイジーパターン」（インスタンスコンテキスト）はここでは必要ありません（彼の初期コードは短く、はるかにクリーンです）。

ただし、この質問のコンテキストで考えることができるこのパターンの1つのアプリケーションは、次のとおりです。ブール論理を型レベルの演算に追加するとします。

data HTrue
data HFalse

-- Will not compile
class And x y r | x y -> r
instance And HTrue HTrue HTrue
instance And a b HFalse -- we do not what to enumerate all the combination here - they all HFalse

ただし、「機能依存性の競合」のため、これはコンパイルされません。そして、私たちはまだ、fundepsなしでこの重複するケースを表現できるように見えます：

class And x y r
instance (r ~ HTrue) => And HTrue HTrue r
instance (r ~ HFalse) => And a b r

b1 = undefined :: And HTrue HTrue r => r   -- HTrue
b2 = undefined :: And HTrue HFalse r => r  -- HFalse

これは間違いなく最も良い方法ではありません（IncoherentInstancesが必要です）。したがって、誰かが別の、より「トラウマ的でない」アプローチを提案できるかもしれません。

于 2010-12-21T04:44:38.970 に答える