0

BitmapData を縮小して PNG として保存するために組み合わせて使用​​するこれらの関数を作成しました。ただし、scaledImage.draw(originalImage, scalingMatrix, null, null, null, true);2 番目の関数を使用してビットマップ データを PNG として保存すると、スムージングが true に設定された線に意図したスムージング効果がありません。結果の画像ファイルはアンチエイリアス処理されていません。ここで私が間違っていることはありますか？ありがとう！

    public static function scaleImage(originalImage:BitmapData, size:int):BitmapData
    {
        // Calculate the scaled size.
        var scale:Number;
        var scaledWidth:Number;
        var scaledHeight:Number;

        if (originalImage.width > originalImage.height)
        {
            scale = (size as Number) / (originalImage.width as Number);
            scaledWidth = size;
            scaledHeight = originalImage.height * scale;
        }
        else
        {
            scale = (size as Number) / (originalImage.height as Number);
            scaledHeight = size;
            scaledWidth = originalImage.width * scale;
        }

        var scalingMatrix:Matrix = new Matrix();
        scalingMatrix.scale(scale, scale);

        // Scale the image.
        var scaledImage:BitmapData = new BitmapData(scaledWidth, scaledHeight, true, 0x00000000);
        scaledImage.draw(originalImage, scalingMatrix, null, null, null, true);

        return scaledImage;
    }

    public static function saveImageAsPNG(image:BitmapData, imageFile:File):void
    {
        // Encode the image as a PNG.
        var pngEncoder:PNGEncoder = new PNGEncoder();
        var imageByteArray:ByteArray = pngEncoder.encode(image);

        // Write the image data to a file.
        var imageFileStream:FileStream = new FileStream();
        imageFileStream.open(imageFile, FileMode.WRITE);
        imageFileStream.writeBytes(imageByteArray);
        imageFileStream.close();                
    }
4

1 に答える 1

0

このコードは機能していたことがわかりました。平滑化された画像を保存していました。私が縮小していた画像は約20Kx20Kピクセルだったので、はっきりしませんでした。そのため、とにかくスムージングでジャギーが現れました。平滑化は、2Kx2Kピクセルのようなより「通常の」サイズの画像で明らかでした

于 2010-12-27T21:34:50.553 に答える