perl - Perlで動的/再帰的にハッシュを構築していますか?

Question

私はPerlを初めて使用し、ハッシュを再帰的に構築しようとしていますが、どこにも行きません。ハッシュを動的に構築するためのチュートリアルを検索してみましたが、ハッシュに関する紹介記事しか見つかりませんでした。正しい方向に私を向けたり、素敵な記事/チュートリアルを提案していただければ幸いです。

次の形式のパスを持つファイルから読み取ろうとしています

one/two/three
four
five/six/seven/eight

そして、私は次のようなハッシュを構築したい

VAR = {
    one : {
        two : {
            three : ""
        }
    }
    four : ""
    five : {
        six : {
            seven : {
                 eight : ""
            }
        }
    }
}

現在使用しているスクリプトは次のとおりです。

my $finalhash = {}; 
my @input = <>;

sub constructHash {
    my ($hashrf, $line) = @_; 
    @elements = split(/\//, $line);
    if(@elements > 1) {
        $hashrf->{shift @elements} = constructHash($hashrf->{$elements[0]}, @elements ); 
    } else {
        $hashrf->{shift @elements} = ""; 
    }
    return $hashrf;
}

foreach $lines (@input) {
    $finalhash = constructHash($finalhash, $lines);
}

score 7 · Accepted Answer

Data::Diverはこのニッチをうまくカバーしているので、人々は車輪の再発明をすべきではありません。

use strict;
use warnings;
use Data::Diver 'DiveVal';
use Data::Dumper;

my $root = {};
while ( my $line = <DATA> ) {
    chomp($line);
    DiveVal( $root, split m!/!, $line ) = '';
}
print Dumper $root;
__DATA__
one/two/three
four
five/six/seven/eight

score 6 · Accepted Answer

これは少し大げさですが、うまくいきます：

sub insert {
  my ($ref, $head, @tail) = @_;
  if ( @tail ) { insert( \%{$ref->{$head}}, @tail ) }
  else         {            $ref->{$head} = ''      }
}

my %hash;
chomp and insert \%hash, split( '/', $_ ) while <>;

これは、確かに初心者にとっては少し高度な autovivification に依存しています。

おそらくあなたの質問に対する答えが少しひねられているのは、ノードのハッシュとは異なる「タイプ」であり、異なる逆参照操作が必要な、葉に空の文字列を要求することです。

score 4 · Accepted Answer

私はこのようなことをしたことがないので、このアプローチは間違っている可能性がありますが、まあ、これが私のショットです:

use 5.013;
use warnings;
use Data::Dumper;

sub construct {
   my $hash = shift;
   return unless @_;

   return construct($hash->{shift()} //= {}, @_);
}

my %hash;

while (<DATA>) {
   chomp;
   construct(\%hash, split m!/!);
}

say Dumper \%hash;

__DATA__
one/two/three
four
five/six/seven/eight

編集：修正！

EDIT2：（と思う）テールコール最適化バージョン。

sub construct {
   my $hash = shift;
   return unless @_;
   unshift @_, $hash->{shift()} //=  @_ ? {} : '';

   goto &construct;
}

score 3 · Accepted Answer

コードを実行したところ、いくつかの問題が見つかりました。

@elementsあなたは適切にスコープしていません。
その再帰を使用すると、自分自身を参照するハッシュを作成していますが、これは望んでいるものではありません。
最も外側の呼び出しでは、2 番目の引数constructHash()は文字列ですが、内部の再帰呼び出しでは、次の配列を渡します。@elements

これを試して。

use Data::Dumper;

my $finalhash = {}; 
my @input = split "\n", <<INPUT;
one/two/three
four
five/six/seven/eight
INPUT

sub constructHash {
    my $line = shift; 
    my ($first, $remainder) = split(/\//, $line,2);

    if ($remainder) {
        return { $first => constructHash($remainder) } ; 
    } else {
        return { $first , "" }; 
    }
}

foreach $lines (@input) {
    my $linehash = constructHash($lines);
    my $firstkey = (keys %$linehash)[0];
#    print Dumper $linehash;
    $finalhash->{$firstkey} = $linehash->{$firstkey};
} 


print Dumper $finalhash;

それは生産します

$VAR1 = {
          'five' => {
                      'six' => {
                                 'seven' => {
                                              'eight' => ''
                                            }
                               }
                    },
          'one' => {
                     'two' => {
                                'three' => ''
                              }
                   },
          'four' => ''
        };

Perl ハッシュは順序付けられていないことに注意してください。

score 1 · Accepted Answer

1

基礎：

于 2010-12-30T00:52:09.127 に答える

perl - Perlで動的/再帰的にハッシュを構築していますか?

5 に答える 5

Related

Reference