hash - KRLのハッシュから空のpick（）を検出する

Question

ハッシュにたくさんのデータがあり、そこから選択しています。選択するデータがある場合とない場合があります。ピック演算子によって何かが見つかったときと見つからなかったときを知るための最良の方法は何ですか？コードでそれに反応することができますか？

Answer 1

pick 演算子は、結果を常に配列で返すようにする 2 番目のオプションのパラメーターを受け取ります。これは、何かが選択された場合、配列の長さが 0 よりも大きくなり、それ以外の場合は 0 になることを意味します。その後、それを使用してやりたいことを実行できます。

http://kynetxappaday.wordpress.com/2011/01/04/day-30-detecting-empty-pick/から取得したコード/アプリの例

ruleset a60x526 {
  meta {
    name "hash-pick-detect"
    description <<
      hash-pick-detect
    >>
    author "Mike Grace"
    logging on
  }

  global {
    dataHash = {
      "one": {
        "name": "Mike"
      }, // number
      "two": {
        "random": 8
      }, // number
      "three": {
        "name": "Alex"
      } // number

    }; // dataHash

  } // global

  rule detect_the_pick {
    select when pageview ".*"
    foreach dataHash setting (key, value)
    pre {
      userName = value.pick("$.name", true);
      length = userName.length();
    }
    if (length > 0) then {
      notify("Key: #{key}","Name: #{userName}<br/>Length: #{length}") with sticky = true;
    }
    notfired {
      raise explicit event empty_pick
        with pickedKey = key;
    }
  }

  rule empty_pick_found {
    select when explicit empty_pick
    pre {
      pickedKey = event:param("pickedKey");
      results =<<
        Key: #{pickedKey}<br/>
        doesn't have a name associated with it to pick from
      >>; //' fixing syntax highlighting
    }
    {
      notify("An empty pick was detected",results) with sticky = true;
    }
  }
}