delphi - 2つのTStreamのコンテンツを比較するDelphi関数？

Question

2つのTStreamの子孫が同じコンテンツを持っているかどうかを比較する必要があります。私にとって唯一の興味深い結果は、ブール値のはい/いいえです。

ストリームのコンテンツをバイトごとにチェックする単純なループをコーディングします。

しかし、既存の関数があるかどうか知りたいです。DelphiXEまたはJCL/JVCLライブラリ内に何も見つかりませんでした。

もちろん、2つのストリームのサイズは同じです。

Answer 1

正確には、Nickolay O.が言ったように、ストリームをブロック単位で読み取り、CompareMemを使用する必要があります。これが例です（サイズテストを含む）...

function IsIdenticalStreams(Source, Destination: TStream): boolean;
const Block_Size = 4096;

var Buffer_1: array[0..Block_Size-1] of byte;
    Buffer_2: array[0..Block_Size-1] of byte;
    Buffer_Length: integer;

begin
  Result := False;

  if Source.Size <> Destination.Size then
    Exit;

  while Source.Position < Source.Size do
    begin
      Buffer_Length := Source.Read(Buffer_1, Block_Size);
      Destination.Read(Buffer_2, Block_Size);

      if not CompareMem(@Buffer_1, @Buffer_2, Buffer_Length) then
        Exit;
    end;

  Result := True;
end;

Answer 2

daemon_xによって投稿されたIsIdenticalStreams関数は優れていますが、正しく機能するには1つの調整が必要です。（Uwe Raabeはすでに問題をキャッチしています。）ループを開始する前にストリームの位置をリセットすることが重要です。そうしないと、2つのストリームがこの関数の外部ですでにアクセスされている場合、この手順はおそらく誤ったTRUEを返します。

これは、毎回機能する最終的なソリューションです。命名規則に合わせて関数の名前を変更しました。エレガントなソリューションをありがとうdaemon_x。

function StreamsAreIdentical(Stream1, Stream2: TStream): boolean;
const
  Block_Size = 4096;

var
  Buffer_1: array[0..Block_Size-1] of byte;
  Buffer_2: array[0..Block_Size-1] of byte;
  Buffer_Length: integer;

begin

  Result := False;

  if Stream1.Size <> Stream2.Size then exit;

  // These two added lines are critical for proper operation 
  Stream1.Position := 0;
  Stream2.Position := 0;

  while Stream1.Position < Stream1.Size do
  begin

    Buffer_Length := Stream1.Read(Buffer_1, Block_Size);
    Stream2.Read(Buffer_2, Block_Size);
    if not CompareMem(@Buffer_1, @Buffer_2, Buffer_Length) then exit;

  end;

  Result := True;

end;

Answer 3

そのような組み込み関数はありません。私がお勧めできるのは1つだけです。バイト単位ではなく、16〜64kバイトのブロックを使用して読み取ると、はるかに高速になります。

Answer 4

user532231とMikeからの回答は99％のケースで機能していますが、追加のチェックを行う必要があります。

TStreamの子孫はほとんど何でもかまいません。したがって、ストリームが同じ長さであっても、Stream.Readが同じ量のデータを返すことは保証されません（ストリームの子孫もデータをダウンロードできるため、待機中にreaded=0バイトを返す可能性があります。次のチャンク）。ストリームは完全に異なるメディア上にある可能性もあり、ストリーム読み取りエラーは1つだけで発生する可能性があります。

100％動作するコードの場合、これらすべてのチェックを行う必要があります。マイクから関数を変更しました。

この関数を使用して、たとえばStream1と同一でない場合にストリーム2を書き換える場合は、すべてのエラーをチェックする必要があります。関数の結果がTrueの場合、すべて問題ありませんが、Falseの場合、ストリームが実際に異なるか、または何らかのエラーが発生したかどうかを確認するのは非常に賢明です。

編集：いくつかの追加チェック、StreamsAreIdenticalに基づくFilesAreIdentical関数、および使用例を追加しました。

// Usage example

var lError: Integer;
...
 if FilesAreIdentical(lError, 'file1.ext', 'file2.ext')
    then Memo1.Lines.Append('Files are identical.')
    else case lError of
           0: Memo1.Lines.Append('Files are NOT identical!');
           1: Memo1.Lines.Append('Files opened, stream read exception raised!');
           2: Memo1.Lines.Append('File does not exist!');
           3: Memo1.Lines.Append('File open exception raised!');
         end; // case
...

// StreamAreIdentical

function StreamsAreIdentical(var aError: Integer;
                             const aStream1, aStream2: TStream;
                             const aBlockSize: Integer = 4096): Boolean;

var
  lBuffer1: array of byte;
  lBuffer2: array of byte;
  lBuffer1Readed,
  lBuffer2Readed,
  lBlockSize: integer;

begin
  Result:=False;
  aError:=0;
  try
    if aStream1.Size <> aStream2.Size
       then Exit;

    aStream1.Position:=0;
    aStream2.Position:=0;

    if aBlockSize>0
       then lBlockSize:=aBlockSize
       else lBlockSize:=4096;

    SetLength(lBuffer1, lBlockSize);
    SetLength(lBuffer2, lBlockSize);

    lBuffer1Readed:=1; // just for entering while

    while (lBuffer1Readed > 0) and (aStream1.Position < aStream1.Size) do
    begin
      lBuffer1Readed := aStream1.Read(lBuffer1[0], lBlockSize);
      lBuffer2Readed := aStream2.Read(lBuffer2[0], lBlockSize);

      if (lBuffer1Readed <> lBuffer2Readed) or ((lBuffer1Readed <> lBlockSize) and (aStream1.Position < aStream1.Size))
         then Exit;

      if not CompareMem(@lBuffer1[0], @lBuffer2[0], lBuffer1Readed)
         then Exit;
    end; // while

    Result:=True;
  except
    aError:=1; // stream read exception
  end;
end;


// FilesAreIdentical using function StreamsAreIdentical

function FilesAreIdentical(var aError: Integer;
                           const aFileName1, aFileName2: String;
                           const aBlockSize: Integer = 4096): Boolean;

var lFileStream1,
    lFilestream2: TFileStream;

begin
 Result:=False;
 try
   if not (FileExists(aFileName1) and FileExists(aFileName2))
      then begin
        aError:=2; // file not found
        Exit;
      end;

   lFileStream1:=nil;
   lFileStream2:=nil;
   try
     lFileStream1:=TfileStream.Create(aFileName1, fmOpenRead or fmShareDenyNone);
     lFileStream2:=TFileStream.Create(aFileName2, fmOpenRead or fmShareDenyNone);
     result:=StreamsAreIdentical(aError, lFileStream1, lFileStream2, aBlockSize);
   finally
     if lFileStream2<>nil
        then lFileStream2.Free;

     if lFileStream1<>nil
        then lFileStream1.Free;
   end; // finally
 except
   aError:=3; // file open exception
 end; // except
end;