0

を含むセルの値を?変数と比較すると、常にtrueが返されます。これを防ぐ方法はありますか？これが私の現在のコードです：

'Option Explicit
Dim hws As Worksheet
Set hws = ActiveSheet
Dim rng As Range, rng2 As Range
Dim letters(2, 2)
alpha = Range("CipherTable").Value

For x = 1 To 7
  For y = 1 To 7
    If alpha(x, y) = rng.Cells(i, j + 1).Value Then
      letters(2, 1) = x
      letters(2, 2) = y
    End If
  Next y
Next x

ちなみに、alphaは次のようになります。

A   B   C   D   E   F   G
H   I   J   K   L   M   N
O   P   Q   R   S   T   U
V   W   X   Y   Z   1   2
3   4   5   6   7   8   9
0   ;   :   '   "   .   ,
(   )   _   -   +   ?   !

これは常にA、alpha（1,1）にあるを返します。考えてみると、それぞれ7になっているので、なぜ戻ってこないのかわかりません!。これを回避して、実際に一致する場合にのみtrueを返すにはどうすればよいですか？

4

2 に答える 2

1

私が理解している限り、置換アルゴリズムを作成したいと考えています。2 次元の暗号テーブルを使用する特別な理由がない場合は、次のような 1 次元のアプローチを使用します。

Function Cipher(Argument As String) As String
Dim Model As String
Dim Subst As String
Dim Idx As Integer
Dim MyPos As Integer

    Cipher = ""
    ' note double quotation mark within string
    Model = "ABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890;:'"".,()_-+?!"
    Subst = "ABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890;:'"".,()_-+?!"

    For Idx = 1 To Len(Argument)
        ' get position from Model
        MyPos = InStr(1, Model, UCase(Mid(Argument, Idx, 1)))
        ' return character from substitution pattern
        If MyPos <> 0 Then Cipher = Cipher & Mid(Subst, MyPos, 1)
    Next Idx

End Function

この関数を呼び出す

Sub Test()
    Debug.Print Cipher("The quick brown (?) fox 123 +-")
End Sub

結果は(またはTHEQUICKBROWN(?)FOX123+-に空白を入れることができないため)ModelSubst

今Substに変更

Subst = "!?+-_)(,.""':;0987654321ZYXWVUTSRQPONMLKJIHGFEDCBA"

結果は4,_73.+'?6910GBF)9ZWVUCD

上記を暗号関数にTHEQUICKBROWN(?)FOX123+-入力すると、対称置換から期待されるように再び終了します。

于 2011-01-11T08:56:06.537 に答える
0

次のことを試しましたが、期待どおりの結果が得られました（疑問符を見つけることができました）。

（1）上記のように、ワークシートにCipherTable範囲を作成しました。

（2）上記のコードと同様の関数QMを作成しました。

（3）= QM（cell-ref）のスタイルで数式を入力しました。

それはうまくいきました。機能QM：

Public Function QM(theChar)

    Dim CipherTable
    Dim x As Integer
    Dim y As Integer

    CipherTable = Range("CipherTable").Value

    For x = 1 To 7
        For y = 1 To 7
            If CipherTable(x, y) = theChar Then
                QM = "X" & x & "Y" & y
                Exit Function
            End If
        Next y
    Next x

    QM = ""

End Function

====

また、もっと直接的なことを試してみたところ、期待どおりの反応が得られました。

Public Sub QM2()

    Dim questMark As Range
    Dim someChar As String
    Set questMark = Range("CipherTable").Cells(7, 6)

    someChar = "A"
    Debug.Print questMark = someChar

End Sub
于 2011-01-14T15:32:09.090 に答える