14

machine1 に Mnesia データベース / スキーマを作成しました。ノードには mypl@machine1 という名前が付けられました。次に、machine1 が故障したため、すべてのファイルを machine2 に移動しました。コードが「mypl@machine1」という名前で実行されている限り、すべて正常に実行されます。現在 machine2 で実行されているため、これは明らかに混乱を招きます。

ノード名「mypl@machine2」で Erlang を起動すると、Mnesia データベースが空に見えます。

Mnesia データベースのノードの名前を machine1 から machine2 に変更するにはどうすればよいですか?

4

2 に答える 2

14

これは単一のノード(誰か?)でオンラインで実行できるとは思いませんが、2つのノードを実行してテーブルのコピーを追加するだけでなく、バ​​ックアップ/復元を介して実行することもできます。Mnesiaユーザーガイドセクション6.9.1には、mnesia:traverse_backupを使用して、mnesiaバックアップファイルのスキーマテーブル(以下に表示)のノード名を変更するコードがあります。おそらく使用する必要のあるモジュール名はですmnesia_backup

このコードを使用すると、次のことが必要になります。

%% On mypl@machine1
mnesia:backup("/path/to/mnesia.backup").
change_node_name(mnesia_backup, mypl@machine1, mypl@machine2,
                 "/path/to/mnesia.backup", "/path/to/new.mnesia.backup").
%% On mypl@machine2
mnesia:restore("/path/to/new.mnesia.backup", []).

で最初にスキーマを作成する必要があるかどうかはわかりませんmypl@machine2

ユーザーガイドのノード名コードの変更:

change_node_name(Mod, From, To, Source, Target) ->
    Switch =
        fun(Node) when Node == From -> To;
           (Node) when Node == To -> throw({error, already_exists});
           (Node) -> Node
        end,
    Convert =
        fun({schema, db_nodes, Nodes}, Acc) ->
                {[{schema, db_nodes, lists:map(Switch,Nodes)}], Acc};
           ({schema, version, Version}, Acc) ->
                {[{schema, version, Version}], Acc};
           ({schema, cookie, Cookie}, Acc) ->
                {[{schema, cookie, Cookie}], Acc};
           ({schema, Tab, CreateList}, Acc) ->
                Keys = [ram_copies, disc_copies, disc_only_copies],
                OptSwitch =
                    fun({Key, Val}) ->
                            case lists:member(Key, Keys) of
                                true -> {Key, lists:map(Switch, Val)};
                                false-> {Key, Val}
                            end
                    end,
                {[{schema, Tab, lists:map(OptSwitch, CreateList)}], Acc};
           (Other, Acc) ->
                {[Other], Acc}
        end,
    mnesia:traverse_backup(Source, Mod, Target, Mod, Convert, switched).
于 2009-01-21T13:04:39.033 に答える
2

回避策は移行です。mnesia クラスターを起動して、すべてのテーブルとスキーマを他のノードに移行するだけです。元から削除して忘れたよりも。

于 2009-01-21T08:42:07.193 に答える