7

mod_perl2で実行されているコードから実行時間の長いプロセスをフォークするのに問題があります。

ほとんどすべてが機能しますが、フォークされたプロセスはApacheのログファイルへのオープンハンドルを保持しているようです-これは、プロセスの実行中にApacheが再起動しないことを意味します（「ログファイルを開けませんでした」というメッセージが表示されます）。

これが私が使用しているコードです：

use POSIX; # required for setsid

# Do not wait for child processes to complete
$SIG{CHLD} = 'IGNORE';

# fork (and make sure we did!)
defined (my $kid = fork) or die "Cannot fork: $!\n";

if ($kid) {
    return (1, $kid);
}else {
    # chdir to /, stops the process from preventing an unmount
    chdir '/' or die "Can't chdir to /: $!";

    # dump our STDIN and STDOUT handles
    open STDIN, '/dev/null' or die "Can't read /dev/null: $!";
    open STDOUT, '>/dev/null' or die "Can't write to /dev/null: $!";

    # redirect for logging
    open STDERR, '>', $log_filename or die "Can't write to log: $!";

    # Prevent locking to apache process
    setsid or die "Can't start a new session: $!";

    # execute the command
    exec( $cmd, @args );

    die "Failed to exec";
}

mod_perl1の時代に、$r->cleanup_for_execこの問題を解決するために使用したことを思い出しますが、mod_perl2ではサポートされていないようです。（編集：どうやらそれはもう必要ありません..）

これらの問題なしにmod_perl2から長時間実行プロセスを正しく開始する方法に関するアドバイスをいただければ幸いです。

4

3 に答える 3

2

あなたはおそらくこの議論を読みたいと思うでしょう。物事を準備する方法を知らない限り、mod_perl をフォークするべきではないようです。Apache2::SubProcessなどのモジュールを使用する必要があります

于 2009-01-23T03:16:53.730 に答える
1

フォークの前にSTDIN/STDOUTハンドルを閉じてみてください。

于 2009-01-23T02:38:35.007 に答える
0

私の (以前は mod_perl、現在は FCGI) コードでは、「if ($kpid)」の「else」節に、

    close STDIN;
    close STDOUT;
    close STDERR;
    setsid();

また、私が忘れていた理由で、すぐにもう一度フォークし、その子で STDIN、STDOUT、および STDERR を再度開きます。

したがって、次のようになります。

$SIG{CHLD} = 'IGNORE';

# This should flush stdout.
my $ofh = select(STDOUT);$| = 1;select $ofh;

my $kpid = fork;
if ($kpid)
{
    # Parent process
    waitpid($kpid, 0);
}
else
{
    close STDIN;
    close STDOUT;
    close STDERR;
    setsid();
    my $gpid = fork;
    if (!$gpid)
    {
        open(STDIN, "</dev/null") ;#or print DEBUG2 "can't redirect stdin\n";
        open(STDOUT, ">/dev/null") ;#or print DEBUG2 "can't redirect stdout\n";
        open(STDERR, ">/dev/null") ;#or print DEBUG2 "can't redirect stderr\n";
        # Child process
        exec($pgm, @execargs) ;# or print DEBUG2 "exec failed\n";
    }
    exit 0;
}
于 2009-01-23T03:12:04.237 に答える