8

文字が変わる可能性のあるドライブを参照しようとしています。ラベルで参照したい (例: バッチ ファイル内の MyLabel (v:)。V:\ で参照できます。MyLabel で参照したいです。

(これは Experts Echange に 1 か月間回答なしで投稿されました。SO が回答する速さを見てみましょう)

4

4 に答える 4

7

前の回答は、過度に複雑であるか、バッチ ファイルに特に適していないように思われます。

この単純な 1 つのライナーは、目的のドライブ文字を変数 myDrive に配置する必要があります。もちろん、「My Label」を実際のラベルに変更してください。

for /f %%D in ('wmic volume get DriveLetter^, Label ^| find "My Label"') do set myDrive=%%D

(バッチ ファイルではなく) コマンド ラインから実行する場合は、両方の場所で %%D を %D に変更する必要があります。

変数が設定されると、 を使用してドライブを参照できます%myDrive%。例えば

dir %myDrive%\someFolder
于 2012-01-30T15:56:06.880 に答える
1

これには、WMI クエリ言語を使用できます。例については、http://msdn.microsoft.com/en-us/library/aa394592 (VS.85).aspx をご覧ください。探している情報は、たとえば、Win32_LogicalDisk クラスのプロパティ VolumeName ( http://msdn.microsoft.com/en-us/library/aa394173(VS.85).aspx ) を通じて入手できます。

SELECT * FROM Win32_LogicalDisk WHERE VolumeName="MyLabel"

于 2008-09-06T21:32:43.400 に答える
1

このバット ファイルは、ドライブ ラベルからドライブ文字を取得します。

Option Explicit
Dim num, args, objWMIService, objItem, colItems

set args = WScript.Arguments
num = args.Count

if num <> 1 then
   WScript.Echo "Usage: CScript DriveFromLabel.vbs <label>"
   WScript.Quit 1
end if

Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_LogicalDisk")

For Each objItem in colItems
  If strcomp(objItem.VolumeName, args.Item(0), 1) = 0 Then
    Wscript.Echo objItem.Name
  End If
Next

WScript.Quit 0

次のように実行します。

 cscript /nologo DriveFromLabel.vbs label
于 2008-09-06T21:49:03.423 に答える
1

以下は、ボリューム ラベルからドライブ文字を検索する単純なバッチ スクリプト getdrive.cmd です。「getdrive MyLabel」または getdrive 「My Label」を呼び出すだけです。

@echo off
setlocal

:: Initial variables
set TMPFILE=%~dp0getdrive.tmp
set driveletters=abcdefghijklmnopqrstuvwxyz
set MatchLabel_res=

for /L %%g in (2,1,25) do call :MatchLabel %%g %*

if not "%MatchLabel_res%"=="" echo %MatchLabel_res%

goto :END


:: Function to match a label with a drive letter. 
::
:: The first parameter is an integer from 1..26 that needs to be 
:: converted in a letter. It is easier looping on a number
:: than looping on letters.
::
:: The second parameter is the volume name passed-on to the script
:MatchLabel

:: result already found, just do nothing 
:: (necessary because there is no break for for loops)
if not "%MatchLabel_res%"=="" goto :eof

:: get the proper drive letter
call set dl=%%driveletters:~%1,1%%

:: strip-off the " in the volume name to be able to add them again further
set volname=%2
set volname=%volname:"=%

:: get the volume information on that disk
vol %dl%: > "%TMPFILE%" 2>&1

:: Drive/Volume does not exist, just quit
if not "%ERRORLEVEL%"=="0" goto :eof

set found=0
for /F "usebackq tokens=3 delims=:" %%g in (`find /C /I "%volname%" "%TMPFILE%"`) do set found=%%g

:: trick to stip any whitespaces
set /A found=%found% + 0


if not "%found%"=="0" set MatchLabel_res=%dl%:
goto :eof








:END

if exist "%TMPFILE%" del "%TMPFILE%"
endlocal
于 2008-09-16T05:11:28.883 に答える