emacs - 特定の拡張子を持つファイルのバックアップをオフにする Emacs 変数はありますか?

Question

たとえば、さまざまなデータ ファイルを編集する場合、バックアップ データは役に立たず、実際にツールが機能しなくなります。そのため、名前に正規表現を含むファイルのバックアップを無効にできるようにしたいと考えています。

ジャスティン

Answer 1

このような質問については、他のオンライン リソースを参照するだけでは不十分ですが、これはあなたのニーズにぴったりのようです。

http://anirudhs.chaosnet.org/blog/2005.01.21.html

そのページに記載されている内容をセットアップしたら、emacs のバージョンに応じて、これを.emacsまたはファイルに追加するだけです。.emacs.d/init.el

(setq auto-mode-alist (append '(("\\.ext1$" . sensitive-mode)) auto-mode-alist))
(setq auto-mode-alist (append '(("\\.ext2$" . sensitive-mode)) auto-mode-alist))
(setq auto-mode-alist (append '(("\\.ext3$" . sensitive-mode)) auto-mode-alist))
(setq auto-mode-alist (append '(("\\.ext4$" . sensitive-mode)) auto-mode-alist))

\\.ext1$、などは、バックアップ\\.ext2$したくないファイル名に一致する正規表現です。

Answer 2

組み込みのEmacs機能を使用したい場合は、次のようにします。

(defvar my-backup-ignore-regexps (list "foo.*" "\\.bar$")
  "*List of filename regexps to not backup")

(defun my-backup-enable-p (name)
  "Filter certain file backups"
  (when (normal-backup-enable-predicate name)
    (let ((backup t))
      (mapc (lambda (re)
              (setq backup (and backup (not (string-match re name)))))
            my-backup-ignore-regexps)
      backup)))

(setq backup-enable-predicate 'my-backup-enable-p)

Answer 3

バックアップ/自動保存ファイルをホームディレクトリに置くようにいつでもemacsに依頼できます。

http://amitp.blogspot.com/2007/03/emacs-move-autosave-and-backup-files.html

(defvar user-temporary-file-directory
  (concat temporary-file-directory user-login-name "/"))
(make-directory user-temporary-file-directory t)
(setq backup-by-copying t)
(setq backup-directory-alist
      `(("." . ,user-temporary-file-directory)
        (,tramp-file-name-regexp nil)))
(setq auto-save-list-file-prefix
      (concat user-temporary-file-directory ".auto-saves-"))
(setq auto-save-file-name-transforms
      `((".*" ,user-temporary-file-directory t)))