XMLデータモデルでは、名前空間ノードは実際には親要素から読み取られませんが、各要素には独自の名前空間ノードがあります。したがって、ルート要素に新しいデフォルトの名前空間を追加するだけでは機能しませんが、次のようなドキュメントになります
<root xmlns="namespaceURL">
<child xmlns=""/>
...
</root>
xmlns=""子要素に空のデフォルトの名前空間が表示されていることに注意してください。実際に行う必要があるのは、すべてのノードの名前空間を変更するか、目的のデフォルトの名前空間で新しいドキュメントを作成し、古いドキュメントの内容、要素、属性名などを新しいドキュメントにコピーすることです。これらは、元のドキュメントを再帰的に調べることで実行できます。Java DOMの実装では、これは面倒な作業になる可能性があると聞いています。ショートカットの1つは、名前空間を認識しないDOMを使用してドキュメントを読み取り、新しいデフォルトの名前空間を属性として追加することです。他の解決策は、XSLT変換を使用して名前空間を変更することです。これは、実際にはXSLT変換を介して出力を既に生成しているため、この場合は非常に適しているようです。
このXSLTスタイルシートを使用して、新しいデフォルトの名前空間とスキーマの場所をルート要素に追加します。このスタイルシートは古い名前空間を保持しますが、以前は名前空間がなかった場合は、すべての要素を新しいデフォルトの名前空間に追加します。
<xsl:stylesheet
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">
<!-- Template to add a default namespace to a document -->
<!-- Elements without a namespace are "moved" to default namespace -->
<!-- Elements with a namespace are copied as such -->
<!-- string for default namespace uri and schema location -->
<xsl:variable name="ns" select="'namespaceURL'"/>
<xsl:variable name="schemaLoc" select="'namespaceURL pathToMySchema.xsd'"/>
<!-- template for root element -->
<!-- adds default namespace and schema location -->
<xsl:template match="/*" priority="1">
<xsl:element name="{local-name()}" namespace="{$ns}">
<xsl:attribute name="xsi:schemaLocation"
namespace="http://www.w3.org/2001/XMLSchema-instance">
<xsl:value-of select="$schemaLoc"/>
</xsl:attribute>
<xsl:apply-templates select="@* | node()"/>
</xsl:element>
</xsl:template>
<!--template for elements without a namespace -->
<xsl:template match="*[namespace-uri() = '']">
<xsl:element name="{local-name()}" namespace="{$ns}">
<xsl:apply-templates select="@* | node()"/>
</xsl:element>
</xsl:template>
<!--template for elements with a namespace -->
<xsl:template match="*[not(namespace-uri() = '')]">
<xsl:copy>
<xsl:apply-templates select="@* | node()"/>
</xsl:copy>
</xsl:template>
<!--template to copy attributes, text, PIs and comments -->
<xsl:template match="@* | node()">
<xsl:copy>
<xsl:apply-templates select="@* | node()"/>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
でトランスフォーマーを作成する代わりに
Transformer trans = transfac.newTransformer();
（ID変換を行うスタイルシートを作成します）、XSLT入力ソースを作成し、それをパラメーターとしてnewTransformer()
javax.xml.transform.Source xsltSource = new javax.xml.transform.stream.StreamSource(xsltFile);
Transformer trans = transFact.newTransformer(xsltSource);
ここで、xsltFileはFileそのXSLTファイルを指すオブジェクトです。
transform()必要に応じて出力プロパティを設定し、サンプルコードのように呼び出します。結果はあなたが望むものになるはずですが、私はこれをJavaでテストしていません。指定されたXSLTファイルは、いくつかの些細なケースでテストされており、この回答の最後にサンプルの入力と出力があります。
いくつかのマイナーな注意：
- このプロセスでは、元のドキュメントオブジェクトは変更されません。新しいデフォルトの名前空間は、
transform()メソッドの出力にのみ表示されます。
- スキーマインスタンス名前空間の名前空間プレフィックスは通常、サンプルコードのようにで
xsi:はありません（スキーマ定義（および）で使用されます）。xs:xs:xsd:
上記のXSLTスタイルシートの入力と出力の例
入力：
<root>
<child>text</child>
<child attribute="attr-value"/>
<?pi-target pi-content?>
<nsx:ns-child xmlns:nsx="ns1x">
<no-ns-child>text</no-ns-child>
<!-- comment -->
<nsx:ns-child nsx:ns-attribute="nsx-attr-value">text</nsx:ns-child>
</nsx:ns-child>
<defns-child xmlns="default-ns">
<def-child attr="val">text</def-child>
<child xmlns=""/>
</defns-child>
<child>text</child>
</root>
出力：
<?xml version="1.0" encoding="UTF-8"?>
<root xmlns="namespaceURL" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="namespaceURL pathToMySchema.xsd">
<child>text</child>
<child attribute="attr-value"/>
<?pi-target pi-content?>
<nsx:ns-child xmlns:nsx="ns1x">
<no-ns-child>text</no-ns-child>
<!-- comment -->
<nsx:ns-child nsx:ns-attribute="nsx-attr-value">text</nsx:ns-child>
</nsx:ns-child>
<defns-child xmlns="default-ns">
<def-child attr="val">text</def-child>
<child xmlns="namespaceURL"/>
</defns-child>
<child>text</child>
</root>