2

ピラミッド プロジェクトで使用される「paster serve」コマンドを開始および停止するためのショートカット キーをいくつか作成しようとしています。ここに私のelispコードがあります:

(defun search-for-file (file dir)
  "Recursively searches up the directory tree for a given filename"
  (if (equal "/" dir)
      nil
    (if (member file (directory-files dir))
        (concat (file-name-as-directory dir) file)
      (progn
        (cd-absolute dir)
        (cd "..")
        (search-for-file file default-directory)))))

(defun paster-serve-start ()
  (interactive)
  (progn
    (start-process
     "paster-serve" "server"
     "paster" "serve" (search-for-file "development.ini" ".") "--reload" "-v")
    (switch-to-buffer "server")))

(defun paster-serve-stop ()
  (interactive)
  (progn
    (setq proc (get-process "paster-serve"))
    (setq buf (get-buffer "server"))
    (quit-process proc)
    (kill-buffer buf)))

(define-prefix-command 'paster-map)
(global-set-key (kbd "C-p") 'paster-map)
(define-key paster-map (kbd "s") 'paster-serve-start)
(define-key paster-map (kbd "e") 'paster-serve-stop)

default-directoryこれらの関数は、development.ini が存在する場所 (例: ~/myproject)に設定されたバッファーから期待どおりに機能します。ただし、プロジェクトのベース ディレクトリ (例: ~/myproject/myproject/templates) の下のディレクトリにいるときにこの作業を行うことを望んでいました - development.ini が存在するディレクトリの下のディレクトリからプロセスを実行しようとすると、このエラー:

IOError: File '/home/myuser/myproject/~/myproject/development.ini' not found

ここで私が間違っていることに光を当てることができる賢明なemacsマスターはいますか？

4

1 に答える 1

2

私はこれらすべてのcd機能に少し警戒しています。search-for-fileの同様の関数に基づいて、次の の別の定義を試してくださいproject-local-variables.el。

(defun search-for-file (file dir)
  "Look up the file in and above `dir'."
 (let ((f (expand-file-name file dir))
       (parent (file-truename (expand-file-name ".." dir))))
   (cond ((string= dir parent) nil)
         ((file-exists-p f) f)
         (t (search-for-file file parent)))))
于 2011-02-11T08:25:24.603 に答える