2

これが私が書いたスクリプトで、EXCEPTION ブロックに奇妙な構文エラーがあります。例外ブロックを削除すると、スクリプトは正しくコンパイルされます。しかし、書き戻すとすぐにエラーが発生します

Error(58,11): PLS-00103: Encountered the symbol "EXCEPTION" when expecting one of the following:     ( begin case declare else elsif end exit for goto if loop mod    null pragma raise return select update while with    <an identifier> <a double-quoted delimited-identifier>    <a bind variable> << continue close current delete fetch lock    insert open rollback savepoint set sql execute commit forall    merge pipe purge

ここにスクリプトがあります

LOOP
  BEGIN
    SAVEPOINT check_point;

    EXIT WHEN DBMS_SQL.FETCH_ROWS (cursor_handle) = 0;
    DBMS_SQL.COLUMN_VALUE (cursor_handle, 1,  cc , col_err, actual_len);
    DBMS_SQL.COLUMN_VALUE (cursor_handle, 2,  di, col_err, actual_len);

    IF INSTR (cc, '_') <> 0 THEN
      cc := Trim (cc);
      cc := Upper(cc);
      cc := substr(cc,4,2);

      EXECUTE IMMEDIATE 'UPDATE  ' || dest || ' SET cc = :v1 WHERE di = :v2' 
        USING cc, di;

      if SQL%ROWCOUNT > 0 THEN
        inserts := inserts + 1;
        counter := counter + 1;
        IF counter > 500 THEN
          counter := 0;
          COMMIT;
        END IF;
      END IF;

      EXCEPTION
        WHEN DUP_VAL_ON_INDEX THEN
          dups := dups+1;
          ROLLBACK TO check_point;
        WHEN VALUE_ERROR THEN
          valerr := valerr +1;
          ROLLBACK TO check_point;
        WHEN OTHERS THEN
          DBMS_OUTPUT.PUT_LINE('errno: ' || TO_CHAR(SQLCODE) || ' Msg: ' || SQLERRM);
          otherexc := otherexc +1;
        IF otherexc > 50 THEN 
          EXIT;
        END IF;
        ROLLBACK TO check_point;              
    END IF;
  END;
END LOOP;

このような質問をするのは非常に面倒ですが、それがどのエラーなのかわかりません。私は Pl/SQL のリーマンです。

4

1 に答える 1

3

エラーは、EXCEPTION 句がIF INSTR (cc, '_') <> 0IF ステートメント内にあるように見えますが、ループの先頭にある BEGIN ステートメントに EXCEPTION を一致させたいようです。END IF を移動したいと考えています。ここで行うように、例外のIF INSTR (cc, '_') <> 0前に

LOOP
  BEGIN
    SAVEPOINT check_point;

    EXIT WHEN DBMS_SQL.FETCH_ROWS (cursor_handle) = 0;
    DBMS_SQL.COLUMN_VALUE (cursor_handle, 1,  cc , col_err, actual_len);
    DBMS_SQL.COLUMN_VALUE (cursor_handle, 2,  di, col_err, actual_len);

    IF INSTR (cc, '_') <> 0 THEN
      cc := Trim (cc);
      cc := Upper(cc);
      cc := substr(cc,4,2);

      EXECUTE IMMEDIATE 'UPDATE  ' || dest || ' SET cc = :v1 WHERE di = :v2' 
        USING cc, di;

      if SQL%ROWCOUNT > 0 THEN
        inserts := inserts + 1;
        counter := counter + 1;
        IF counter > 500 THEN
          counter := 0;
          COMMIT;
        END IF; -- IF counter > 500
      END IF; -- IF SQL%ROWCOUNT > 0
    END IF; -- INSTR (cc, '_') <> 0


  EXCEPTION
    WHEN DUP_VAL_ON_INDEX THEN
      dups := dups+1;
      ROLLBACK TO check_point;
    WHEN VALUE_ERROR THEN
      valerr := valerr +1;
      ROLLBACK TO check_point;
    WHEN OTHERS THEN
      DBMS_OUTPUT.PUT_LINE('errno: ' || TO_CHAR(SQLCODE) || ' Msg: ' || SQLERRM);
      otherexc := otherexc +1;
      IF otherexc > 50 THEN 
        EXIT;
      END IF;
      ROLLBACK TO check_point;              
  END;
END LOOP;

そうは言っても、おそらくコードを少し書き直すでしょう。500 行ごとにコミットすることは、ほぼ間違いなくエラーです。私はあなたの WHEN OTHERS 例外ハンドラーに非常に懐疑的です-少なくともエラーをテーブルに書き込むか、エラーのコレクションにデータを入力する必要があると思います.表示されます。

LOOP
  SAVEPOINT check_point;

  EXIT WHEN DBMS_SQL.FETCH_ROWS (cursor_handle) = 0;
  DBMS_SQL.COLUMN_VALUE (cursor_handle, 1,  cc , col_err, actual_len);
  DBMS_SQL.COLUMN_VALUE (cursor_handle, 2,  di, col_err, actual_len);

  IF INSTR (cc, '_') <> 0 THEN
    cc := Trim (cc);
    cc := Upper(cc);
    cc := substr(cc,4,2);

    BEGIN
      EXECUTE IMMEDIATE 'UPDATE  ' || dest || ' SET cc = :v1 WHERE di = :v2' 
        USING cc, di;

      if SQL%ROWCOUNT > 0 THEN
        inserts := inserts + 1;
      END IF; 
    EXCEPTION
      WHEN DUP_VAL_ON_INDEX THEN
        dups := dups+1;
        ROLLBACK TO check_point;
      WHEN VALUE_ERROR THEN
        valerr := valerr +1;
        ROLLBACK TO check_point;
      WHEN OTHERS THEN
        DBMS_OUTPUT.PUT_LINE('errno: ' || TO_CHAR(SQLCODE) || ' Msg: ' || SQLERRM);
        otherexc := otherexc +1;
        IF otherexc > 50 THEN 
          EXIT;
        END IF;
        ROLLBACK TO check_point;              
    END;

  END IF; -- INSTR (cc, '_') <> 0
END LOOP;
于 2011-02-18T17:13:10.833 に答える