4

ネーミングフォーマットreport[{field-name}]を使用して、ColdFusionアプリケーションのフォームを作成しています。これにより、RoRまたはCFWheelsを使用すると、すべてのフィールド名を含むreportというバックエンドの構造体が得られます。私はFW/1を使用しているので、すべてのフォームフィールドがフォームスコープに残るのではなく、RCスコープに入れられます。私が言ったように、CFWheelsがそれを行うので、フォームフィールドをColdFusion構造体に変換することが可能であることを私は知っています。アプリケーションにそれを実行させる方法がわかりません。

これが私が話しているフォームの一部です

<dl class="oneColumn">
    <dt class="first"><label for="report[name]">Name</label></dt>
    <dd><input type="text" name="report[name]" class="text" /></dd>
    <dt><label for="report[description]">Description</label></dt>
    <dd><textarea name="report[description]" class="textarea"></textarea></dd>
</dl>
4

2 に答える 2

4

Adamは正しいコンテキストを持っていましたが、彼のコードスニペットは間違っていました。

動作する関数は次のとおりです。

<cffunction name="$createNestedParamStruct" returntype="struct" access="public" output="false">
    <cfargument name="params" type="struct" required="true" />
    <cfscript>
        var loc = {};
        for(loc.key in arguments.params)
        {
            if (Find("[", loc.key) && Right(loc.key, 1) == "]")
            {
                // object form field
                loc.name = SpanExcluding(loc.key, "[");

                // we split the key into an array so the developer can have unlimited levels of params passed in
                loc.nested = ListToArray(ReplaceList(loc.key, loc.name & "[,]", ""), "[", true);
                if (!StructKeyExists(arguments.params, loc.name))
                arguments.params[loc.name] = {};

                loc.struct = arguments.params[loc.name]; // we need a reference to the struct so we can nest other structs if needed
                loc.iEnd = ArrayLen(loc.nested);
                for(loc.i = 1; loc.i lte loc.iEnd; loc.i++) // looping over the array allows for infinite nesting
                {
                    loc.item = loc.nested[loc.i];
                    if (!StructKeyExists(loc.struct, loc.item))
                        loc.struct[loc.item] = {};
                    if (loc.i != loc.iEnd)
                        loc.struct = loc.struct[loc.item]; // pass the new reference (structs pass a reference instead of a copy) to the next iteration
                    else
                        loc.struct[loc.item] = arguments.params[loc.key];
                }
                // delete the original key so it doesn't show up in the params
                StructDelete(arguments.params, loc.key, false);
            }
        }
    </cfscript>
    <cfreturn arguments.params />
</cffunction>

私は自分のアプリケーション（CFWheels以外）でテストしましたが、完全に機能しました。構造体（私の場合はFW / 1のRc構造体）を渡すだけですが、文字列として表示すると、ネストされた構造体を含む構造体が返されます。

例：

<cfscript>
    Struct['hello[world]'] = 1;
    Struct['hello[earth]'] = 2;
    myhello = $createNestedParamStruct(Struct);
    /* Now myhello equals this:
        myhello.hello.world = 1;
        myhello.hello.eath = 2;
    */
</cfscript>
于 2011-03-02T04:53:45.317 に答える
3

したがって、実行する必要のある変更の最も基本的な形式は次のとおりです。

mystruct.name = form["report[name]"];

あなたがする必要があるのは、フォーム構造体をループし、フォームフィールド名を解析してこのような構造体を構築するループを書くことです。すでにCFWheelsのどこかに（関数として）書かれていると思います。見つけて自分で引き出すだけで、頭痛や欲求不満を解消できます。

これだと思いますが、よくわかりません。

<!--- helper method to recursively map a structure to build mapping paths and retrieve its values so you can have your way with a deeply nested structure --->
<cffunction name="$mapStruct" returntype="void" access="public" output="false" mixin="dispatch">
    <cfargument name="map" type="struct" required="true" />
    <cfargument name="struct" type="struct" required="true" />
    <cfargument name="path" type="string" required="false" default="" />
    <cfscript>
        var loc = {};
        for(loc.item in arguments.struct)
        {
            if (IsStruct(arguments.struct[loc.item])) // go further down the rabit hole
            {
                $mapStruct(map=arguments.map, struct=arguments.struct[loc.item], path="#arguments.path#[#loc.item#]");
            }
            else // map our position and value
            {
                arguments.map["#arguments.path#[#loc.item#]"] = {};
                arguments.map["#arguments.path#[#loc.item#]"].value = arguments.struct[loc.item];
            }
        }
    </cfscript>
</cffunction>
于 2011-03-01T15:03:14.583 に答える