0

バックグラウンド：

フラッシュ ゲームを書いているときに問題が発生しました。Polygonal の AS3 データ構造 ( http://code.google.com/p/polygonal/wiki/DataStructures ) を問題なく使用しています。

最近、SmartFoxServer 2X のサポートをゲームに追加しました ( http://www.smartfoxserver.com/ )。SmartFox SWC ファイルをインポートするとすぐに、互換性のないオーバーライドを示す "new LinkedQueue()" 呼び出しで実行時エラーが発生します。

とにかく、Polygonal にバグを報告したところ、SmartFox が古いバージョンのデータ構造を使用しており、それを SWC ファイルに含めていることがわかりました。

私の質問：

SWC ファイルが 2 つしかないことを考えると、それらを強制的に別の名前空間に入れる方法はありますか? これにより、smartfox の古いバージョンと一緒に新しいバージョンを使用できるようになります。

4

1 に答える 1

1

はい、それが本当に重要であり、時間を費やしたい場合は、内部のswfとカタログを変更することでswc内のパッケージを変更することができます。

SWFWireデコンパイラを使用したAIRプロジェクトのサンプルは次のとおりです。

public class SWFWireCompiler extends Sprite
{
    public function SWCEditor()
    {
        stage.nativeWindow.activate();

        var bytes:ByteArray = getBytes('library.swf');

        var swfReader:SWFReader = new SWF10Reader();
        var readResult:SWFReadResult = swfReader.read(new SWFByteArray(bytes));
        readResult.swf.header.signature = SWFHeader.UNCOMPRESSED_SIGNATURE;

        for each(var tag:SWFTag in readResult.swf.tags)
        {
            var abcTag:DoABCTag = tag as DoABCTag;
            if(abcTag)
            {
                for each(var string:StringToken in abcTag.abcFile.cpool.strings)
                {
                    if(string.utf8 == 'de.polygonal.ds')
                    {
                        string.utf8 = 'de.polygonal.ds.old';
                    }
                }
            }
        }

        var swfWriter:SWFWriter = new SWF10Writer();
        var writeResult:SWFWriteResult = swfWriter.write(readResult.swf);

        writeBytes('C:\\output.swf', writeResult.bytes);
    }

    private function getBytes(file:String):ByteArray
    {
        var bytes:ByteArray = new ByteArray();
        var stream:FileStream = new FileStream();
        stream.open(File.applicationDirectory.resolvePath(file), FileMode.READ);
        stream.readBytes(bytes);
        stream.close();
        return bytes;
    }

    private function writeBytes(filename:String, bytes:ByteArray):void
    {
        var file:File = new File(filename);
        var fs:FileStream = new FileStream();
        fs.open(file, FileMode.WRITE);
        fs.writeBytes(bytes);
        fs.close();
    }
}

次に、catalog.xmlで検索/置換を実行してから、再パッケージ化する必要があります。

于 2011-03-04T06:42:13.290 に答える