3

ストロークの不透明度を変更しようとしていますが、HSB カラー モードで変更する方法がわかりません。または、RGB モードに切り替えた場合、時間の経過とともに色を変更するにはどうすればよいですか?

ここに私のコードがあります:(どんな助けでも大歓迎です)

float rainbow=0;
int dir=1;

void setup() {
  size(600, 600);
  background(0);
  colorMode(HSB, 255);
 } 

void draw() {
  if ( rainbow < 255 && dir==1) {
     rainbow++;
  }

  if ( rainbow > 0 && dir==-1) {
    rainbow--;
  }

  if ( rainbow == 255) {
    dir*= -1;
  }

  if ( rainbow == 0) {
    dir*= -1;
  }

  stroke(rainbow, 255, 200);
  line(mouseX,mouseY,width/2,height/2); 

  if (mousePressed){
  stroke(rainbow, 255, 200);
  line(mouseX,mouseY,0,mouseX);
  }

  if (mousePressed){
  stroke(rainbow, 100, 200);
  line(mouseX,mouseY,600,mouseX);
  }
}
4

1 に答える 1

1

stroke()またはfill()関数に不透明度の 4 番目のパラメーターを指定できます。次に例を示します。

void setup(){
  size(500, 500);
  colorMode(HSB, 255);
  background(255);
}

void draw(){
  fill(0, 255, 200, 100);
  ellipse(mouseX, mouseY, 20, 20);
}

RGB モードを使用して、R、G、および B 引数を時間の経過とともに変更することもできることに注意してください。これは、HSB 値を循環するよりも少し複雑になりますが、任意のパターンを作成できます。次に例を示します。

float r = 0;
float g = 0;
float b = 0;

float deltaR = 1;
float deltaG = 2;
float deltaB = 4;

void setup(){
  size(500, 500);
  background(255);
}

void draw(){
  
  r += deltaR;
  g += deltaG;
  b += deltaB;
  
  if(r < 0 || r > 255){
    deltaR *= -1;
    r = constrain(r, 0, 255);
  }
  
  if(g < 0 || g > 255){
   deltaG *= -1;
   g = constrain(g, 0, 255);
  }
  
  if(b < 0 || b > 255){
    deltaB *= -1;
    b = constrain(b, 0, 255);
  }
  
  fill(r, g, b);
  ellipse(mouseX, mouseY, 20, 20);
}
于 2018-11-12T01:46:11.650 に答える