0

私はいくつかの助けを使うことができます。

以下は、私の XML の実例です。

<items>
 <item>  
  <name>Thing 1</name>
  <colors>
    <color>white</color>
    <color>green</color>
  </colors>  
  </item>
 <item>  
  <name>Thing 2</name>
  <colors>
    <color>purple</color>
    <color>white</color>
    <color>black</color>  
  </colors>
 </item>
 <item>  
  <name>Thing 3</name>
   <colors/>
 </item>
</items>

私の xslt のトリミングされたサンプル バージョンは次のとおりです。

<xsl:key name="myGrouping" use="colors/color" match="item"/>  
<xsl:template match="/">
 <xsl:apply-templates select="items" mode="groupingTemplate"/>
</xsl:template>  

<xsl:template mode="groupingTemplate" match="items">  
 <xsl:for-each select="item[count(.|key('myGrouping',colors/color)[1])=1]">  
 <xsl:sort select="colors/color"/>  
 <xsl:if test="count(colors/color)&gt;0">
   <p><xsl:value-of select="colors/color"/></p>
   <xsl:for-each select="key('myGrouping',colors/color)">
   <xsl:sort select="name"/>
    <li><xsl:value-of select="name"/></li>
   </xsl:for-each>
  </xsl:if>
 </xsl:for-each>
</xsl:template>

私がやりたいことは、カラー ノードで XSLT 1.0 (Muenchian メソッドを使用) でグループ化することです。そのため、html 出力は次のようになります。

<p>black</p>  
<li>Thing 2</li>  

<p>green</p>  
<li>Thing 1</li>  

<p>purple</p>  
<li>Thing 2</li>  

<p>white<p>  
<li>Thing 1</li>  
<li>Thing 2</li>

これまでのところ、私のコードはこれを行うことができますが、最初のエントリしか取得できません。つまり、上記の例では、現在の出力は次のとおりです。

<p>white</p>
<li>Thing 1</li>
<li>Thing 2</li>

解決策のヘルプと、これが発生する理由の説明をいただければ幸いです。

ありがとう！ジェフ

4

1 に答える 1

2

多くの髪の毛を引っ張った後、それを理解しました...次のxslがそのトリックを行います 

<xsl:key name="byColor" use="." match="item/colors/color"/>  
<xsl:template match="/">
  <xsl:apply-templates select="items" mode="groupingTemplate"/>
</xsl:template>  

<xsl:template mode="groupingTemplate" match="items">  
  <xsl:for-each select="item/colors/color[count(.|key('byColor',.)[1])=1]">  
  <xsl:sort select="."/>  
  <xsl:if test="count(.)&gt;0">
    <p><xsl:value-of select="."/></p>
    <xsl:for-each select="key('byColor',.)">
     <xsl:sort select="../../name"/>
        <li><xsl:value-of select="../../name"/></li>
    </xsl:for-each>
   </xsl:if>
   </xsl:for-each>
 </xsl:template>
于 2011-03-26T03:31:38.140 に答える