3

これを行う最善の方法は何ですか？ここに私がこれまでに持っているものがあります

(defn line-segment [start end]
  (let [x-direction (abs (- (first end) (first start)))
        y-direction (abs (- (last end) (last start)))]
    (cond
      (= 0 x-direction) (something ...)
      (= 0 y-direction) (something ...))))

これが私の最終目標です

user=> (line-segment [5 6] [5 8])
([5 6] [5 7] [5 8])

はい、対角線はなく、x または y の動きのみです。

ありがとう。

4

2 に答える 2

2

これはかなりエレガントなソリューションだと思います：

(defn line-segment [start end]
  (let [x1 (first start) x2 (first end)
        y1 (last start)  y2 (last end)
        dx (if (> x1 x2) -1 1)
        dy (if (> y1 y2) -1 1)]
    (for [x (range x1 (+ dx x2) dx)
          y (range y1 (+ dy y2) dy)]
      [x y])))

REPL セッション:

user> (line-segment [5 6] [5 8])
([5 6] [5 7] [5 8])
user> (line-segment [5 8] [5 6])
([5 8] [5 7] [5 6])
user> (line-segment [-2 7] [1 7])
([-2 7] [-1 7] [0 7] [1 7])
user> (line-segment [1 7] [-2 7])
([1 7] [0 7] [-1 7] [-2 7])

LazySeqサンプル出力がベクトルとしてフォーマットされていても、この関数は を返します。これは重要ではないと思いました。

于 2011-03-28T04:40:12.710 に答える
0

対角線も使用できる簡単なソリューションは次のとおりです。

(use 'clojure.contrib.math)

(defn line-segment [start end]
  (let [x1 (first start) x2 (first end)
        y1 (last start)  y2 (last end)
        xdiff (- x2 x1)
        ydiff (- y2 y1)
        maxdiff (max (abs xdiff) (abs ydiff))
        dx (/ xdiff maxdiff)
        dy (/ ydiff maxdiff)]
    (for [i (range (inc maxdiff))]
      [(round (+ x1 (* i dx))) (round (+ y1 (* i dy)))])))

dbryneのソリューションと同様に、これはベクトルではなくポイントの遅延シーケンスを返します。これは、後で線分の各ポイントで順番に何かを実行したい場合に最も便利な形式だと思います。

于 2011-03-28T09:38:33.070 に答える